4D Doc Center : SET PICTURE TO LIBRARY

Home

4D v14.3

SET PICTURE TO LIBRARY


SET PICTURE TO LIBRARY ( Bild ; BildRef ; BildName )

Parameter	Typ	Beschreibung
Bild	Bild	Neues Bild
BildRef	Lange Ganzzahl	Referenznummer von Bild aus Bilbbibliothek
BildName	String	Neuer Name des Bildes

Beschreibung

Der Befehl SET PICTURE TO LIBRARY erstellt ein neues Bild oder ersetzt ein Bild in der Bildbibliothek.

Übergeben Sie vor dem Aufruf:

in BildRef die Referenznummer des Bildes (Bereich 1...32767 )
In Bild das Bild selbst.
In BildName den Namen des Bildes (max. 255 Zeichen lang).

Gibt es in der Bildbibliothek bereits ein Bild mit der gleichen Referenznummer, wird der Bildinhalt ersetzt und das Bild mit den in Bild und BildName übergebenen Werten umbenannt.

Existiert die Referenznummer noch nicht, wird ein neues Bild in der Bildbibliothek hinzugefügt.

4D Server: SET PICTURE TO LIBRARY kann nicht in einer Methode verwendet werden, die auf dem Server ausgeführt wird. (Serverprozedur oder Trigger). Der Befehl hat auf dem Server keine Auswirkung.

Warnung: Designobjekte, wie z.B. Einträge in hierarchischen Listen, Menüeinträge, etc. können sich auf Bilder der Bildbibliothek beziehen. Seien Sie also vorsichtig, wenn Sie Bilder der Bildbibliothek per Programmierung ändern.

Hinweis: Übergeben Sie in Bild ein leeres Bild oder in BildRef einen negativen Wert bzw. die Ziffer Null, hat der Befehl keine Auswirkung.

Beispiel 1

Folgendes Beispiel sucht - unabhängig vom aktuellen Inhalt der Bildbibliothek - zuerst eine einmalige Referenznummer für ein Bild und fügt dann ein neues Bild in der Bildbibliothek hinzu:

 PICTURE LIBRARY LIST($alPicRef;$asPicNames)

 Repeat

    $vlPicRef:=1+Abs(Random)

 Until(Find in array($alPicRef;$vlPicRef)<0)

 SET PICTURE TO LIBRARY(vgPicture;$vlPicRef;"New Picture")

Beispiel 2

Folgendes Beispiel importiert Bilder aus einem Dokument auf der Festplatte in die Bildbibliothek, die mit dem dritten Beispiel zum Befehl PICTURE LIBRARY LIST erstellt wurde:

 SET CHANNEL(10;"")

 If(OK=1)

    RECEIVE VARIABLE($vsTag)

    If($vsTag="4DV6PICTURELIBRARYEXPORT")

       RECEIVE VARIABLE($vlNbPictures)

       If($vlNbPictures>0)

          For($vlPicture;1;$vlNbPictures)

             RECEIVE VARIABLE($vlPicRef)

             If(OK=1)

                RECEIVE VARIABLE($vsPicName)

             End if

             If(OK=1)

                RECEIVE VARIABLE($vgPicture)

             End if

             If(OK=1)

                SET PICTURE TO LIBRARY($vgPicture;$vlPicRef;$vsPicName)

             Else

                $vlPicture:=$vlNbPictures+1

                ALERT("Diese Datei ist evtl. beschädigt.")

             End if

          End for

       Else

          ALERT("Diese Datei ist evtl. beschädigt.")

       End if

    Else

       ALERT("Datei “"+Dokument+"” ist keine Bildbibliothek Exportdatei.")

    End if

    SET CHANNEL(11)

    End

Fehlerverwaltung

Reicht der Speicher nicht aus, um das Bild der Bildbibliothek hinzuzufügen, wird Fehler -108 erzeugt. Es können auch E/A Fehler auftreten, wie z.B. die Strukturdatei ist gesperrt. Sie können diese Fehler mit einer Methode zur Fehlerverwaltung ausfindig machen.