4D Doc Center : LIRE PARAMETRE ELEMENT TABLEAUX

4D v14.3

LIRE PARAMETRE ELEMENT TABLEAUX


LIRE PARAMETRE ELEMENT TABLEAUX ( {* ;} liste ; refElément \| * ; tabSélecteurs {; tabValeurs} )

Paramètre	Type	Description
*	Opérateur	Si spécifié, liste est un nom d’objet (chaîne) Si omis, liste est un numéro de référence de liste
liste	RefListe, Chaîne	Numéro de référence de liste (si * omis) ou Nom d'objet de type liste (si * passé)
refElément \| *	Entier long, Opérateur	Numéro de référence d’élément ou 0 pour le dernier élément ajouté à la liste ou * pour l’élément courant de la liste
tabSélecteurs	Tableau texte	Tableau des noms de paramètres
tabValeurs	Tableau texte	Tableau des valeurs de paramètres

Description

La commande LIRE PARAMETRE ELEMENT TABLEAUX permet de récupérer en un seul appel l’ensemble des paramètres (ainsi que, optionnellement, leurs valeurs) associés à l’élément refElément de la liste hiérarchique dont vous avez passé la référence ou le nom d’objet dans le paramètre liste.

Les paramètres associés aux éléments permettent de stocker des informations supplémentaires sur chaque élément. Ils sont définis à l’aide de la commande FIXER PARAMETRE ELEMENT.

Si vous passez le premier paramètre optionnel *, vous indiquez que le paramètre liste est un nom d’objet (chaîne) correspondant à une représentation de liste dans le formulaire. Si vous ne passez pas ce paramètre, vous indiquez que le paramètre liste est une référence de liste hiérarchique (RefListe). Si vous utilisez une seule représentation de liste ou travaillez avec les éléments structurels (le second * est omis), vous pouvez utiliser indifféremment l’une ou l’autre syntaxe. En revanche, si vous utilisez plusieurs représentations d’une même liste et travaillez avec l’élément courant (le second * est passé), la syntaxe basée sur le nom d’objet est requise car chaque représentation peut disposer de son propre élément courant.

LIRE PARAMETRE ELEMENT TABLEAUX retourne les paramètres définis pour l’élément réfElément dans le tableau texte tabSélecteurs. Si le tableau texte tabValeurs est passé, la commande retourne les valeurs associées à chaque paramètre dans ce tableau.

Le tableau tabValeur doit être de type texte. Si vous avez associé des valeurs non-textuelles (type numérique ou booléen), elles sont converties en chaînes (vrai="1", faux="0").

Exemple

Soit la liste hiérarchique suivante :

 <>HL:=Nouvelle liste

 $ID:=30

 AJOUTER A LISTE(<>HL;"Martin";$ID)

     //5 paramètres

 FIXER PARAMETRE ELEMENT(<>HL;$ID;"Firstname";"Phil")

 FIXER PARAMETRE ELEMENT(<>HL;$ID;"Birthday";"15/02/1978")

 FIXER PARAMETRE ELEMENT(<>HL;$ID;"Male";Vrai)   //booléen

 FIXER PARAMETRE ELEMENT(<>HL;$ID;"Age";32)   //numérique

 FIXER PARAMETRE ELEMENT(<>HL;$ID;"City";"Nantes")

Pour plus de simplicité, la liste a été associée à un objet liste de même nom ("<>HL").
Lorsque l’élément "Martin" est sélectionné dans la liste, on peut lire ses paramètres en exécutant le code suivant :

 TABLEAU TEXTE(tNomsParams;0)

 LIRE PARAMETRE ELEMENT TABLEAUX(*;"<>HL";*;tNomsParams)

     // tNomsParams{1} contient "Firstname"

     // tNomsParams{2} contient "Birthday"

     // tNomsParams{3} contient "Male"

     // tNomsParams{4} contient "Age"

     // tNomsParams{5} contient "City"

Si on souhaite récupérer également les valeurs des paramètres, on peut écrire :

 TABLEAU TEXTE(tNomsParams;0)

 TABLEAU TEXTE(tValeursParams;0)

 LIRE PARAMETRE ELEMENT TABLEAUX(*;"<>HL";*;tNomsParams;tValeursParams)

     // tValeursParams{1} contient "Phil"

     // tValeursParams{2} contient "15/02/1978"

     // tValeursParams{3} contient "1"

     // tValeursParams{4} contient "32"

     // tValeursParams{5} contient "Nantes"