4D Doc Center : LIRE METADONNEES IMAGE

4D v14.3

LIRE METADONNEES IMAGE


LIRE METADONNEES IMAGE ( image ; nomMeta ; contenuMeta {; nomMeta2 ; contenuMeta2 ; ... ; nomMetaN ; contenuMetaN} )

Paramètre	Type	Description
image	Image	Image dont vous souhaitez lire les métadonnées
nomMeta	Texte	Nom ou chemin du bloc à lire
contenuMeta	Variable	Contenu de la métadonnée

Description

La commande LIRE METADONNEES IMAGE permet de lire le contenu de métadonnées (ou méta-balises) présentes dans image (champ ou une variable image 4D). Pour plus d’informations sur les métadonnées, reportez-vous à la description de la commande FIXER METADONNEES IMAGE.

Passez dans le paramètre nomMeta une chaîne désignant le type de métadonnée à récupérer. Vous pouvez passer :

une constante du thème "Noms des métadonnées images" contenant un chemin de balise,
le nom d’un bloc complet de métadonnées ("TIFF", "EXIF", "GPS" ou "IPTC"),
une chaîne vide ("").

Passez dans le paramètre contenuMeta la variable destinée à recevoir les métadonnées.

Si vous avez passé un chemin de balise dans nomMeta, contenuMeta contient directement la valeur à lire. La valeur sera convertie dans le type de la variable. Les variables de type texte seront formatées en XML (norme XMP). Vous pouvez passer un tableau lorsque la métadonnée contient plus d’une valeur (c’est le cas notamment pour les balises IPTC Keywords).
Si vous avez passé un nom de bloc ou une chaîne vide dans nomMeta, contenuMeta doit être une référence d’élément DOM XML valide. Dans ce cas, le contenu du bloc désigné (ou de tous les blocs si vous avez passé une chaîne vide dans nomMeta) est recopié dans l’élément référencé.

Exemple 1

Utilisation d’arbres DOM

 $xml:=DOM Creer ref XML("Root") //Création d'un arbre XML DOM

 

     //Réception des métadonnées TIFF

 $_Xml_TIFF:=DOM Creer element XML($xml;"/Root/TIFF")

 LIRE METADONNEES IMAGE(vPicture;"TIFF";$_Xml_TIFF)

 

     //Réception des métadonnées GPS

 $_Xml_GPS:=DOM Creer element XML($xml;"/Root/GPS")

 LIRE METADONNEES IMAGE(vPicture;"GPS";$_Xml_GPS)

Exemple 2

Utilisation de variables

 C_DATE($dateAsDate)

 LIRE METADONNEES IMAGE(vImage;TIFF date time;$dateAsDate)  //retourne uniquement la date car "$dateAsDate" est de type Date

 

 C_TEXTE($dateAsText)

 LIRE METADONNEES IMAGE(vImage;TIFF date time;$dateAsText)  //retourne uniquement la date mais au format XML

 

 C_ENTIER($urgency)

 LIRE METADONNEES IMAGE(vImage;IPTC urgency;$urgency)

Exemple 3

Réception de balises à valeurs multiples dans des tableaux

 TABLEAU TEXTE($tTkeywords;0)

 LIRE METADONNEES IMAGE(vImage;IPTC keywords;$tTkeywords)

Après exécution de la commande, tTkeywords contient par exemple :

 $tTkeywords{1}="france"

 $tTkeywords{2}="europe"

Exemple 4

Réception de balises à valeurs multiples dans une variable texte

 C_TEXTE($vTmots;0)

 LIRE METADONNEES IMAGE(vImage;IPTC keywords;$vTmots)

Après exécution de la commande, vTmots contient par exemple "france;europe".

Variables et ensembles système

La variable système OK retourne 1 si la récupération des métadonnées s’est bien passée, et 0 si une erreur se produit ou si au moins une des balises n’est pas trouvée. Dans tous les cas, les valeurs lisibles sont retournées.