4D Doc Center : PV GET CELL CONTROL

4D View v14

PV GET CELL CONTROL


PV GET CELL CONTROL ( area ; columna ; linea ; tipo ; nomVar ; metodo ; titulo )

Parámetro	Tipo	Descripción
area	Entero largo	Área 4D View
columna	Entero largo	Número de columna de la celda
linea	Entero largo	Número de línea de la celda
tipo	Entero	Tipo de control
nomVar	Cadena	Nombre de la variable de gestión del control
metodo	Cadena	Nombre del método de retrollamada
titulo	Cadena	Título del control

Descripción

El comando PV GET CELL CONTROL obtiene la información sobre el "control" mostrado en la celda designada por columna y linea al interior del area 4D View.

Un control es un objeto de tipo botón, casilla de selección, botón de radio, lista desplegable o un combo box dentro de una celda.

tipo indica el tipo de control (entre los cinco mencionados anteriormente) que figura en la celda. Para definir este parámetro, utilice las constantes del tema PV Controles.

nomVar devuelve el nombre de la variable asociada al control (nombre del array que contiene los valores a mostrar para los controles de tipos lista desplegable y combo box).

metodo contiene el nombre del método de retrollamada relacionado con el control.

titulo contiene la etiqueta del botón, casilla de selección, etc.

Ejemplo

El siguiente método llena las celdas ubicadas debajo de un control con la descripción de este último:

 C_LONGINT($Column;$Row) `Coordenadas de la celda del control

 C_INTEGER($CtrlType) `Tipo de control

 C_STRING(32;$CtrlName) `Nombre del control

 C_STRING(32;$CallbackMethod) `Nombre del método de retrollamada

 C_STRING(32;$Title) `Título del control

 C_STRING(32;$TypeName) `Nombre del tipo de control

 

 PV GET CURRENT CELL(Area;$Column;$Row) `Celda controlada

 PV GET CELL CONTROL(Area;$Column;$Row;$CtrlType;$CtrlName;$CallbackMethod;$Title)

 

 Case of

    :($CtrlType=0)

       $TypeName:="Sin control"

 

    :($CtrlType=pv control push button)

       $TypeName:="botón"

 

    :($CtrlType=pv control radio button)

       $TypeName:="botón radio"

 

    :($CtrlType=pv control check box)

       $TypeName:="casilla de selección"

 

    :($CtrlType=pv control drop down)

       $TypeName:="drop-down list"

 

    :($CtrlType=pv control combo box)

       $TypeName:="combo box"

 End case

 

 PV SET CELL TEXT VALUE(Area;$Column;$Row+1;"Type: "+$TypeName)

 PV SET CELL TEXT VALUE(Area;$Column;$Row+2;"Name: "+$CtrlName)

 PV SET CELL TEXT VALUE(Area;$Column;$Row+3;"Title: "+$Title)

 PV SET CELL TEXT VALUE(Area;$Column;$Row+4;"Method: "+$CallbackMethod)