4D Doc Center : PV FIELDS LIST TO CELLS

4D View v14

PV FIELDS LIST TO CELLS


PV FIELDS LIST TO CELLS ( area ; direccion ; columnas ; lineas ; conversiones ; master ; tablas ; campos )

Parámetro	Tipo	Descripción
area	Entero largo	Área 4D View
direccion	Entero	0 = Línea; 1 = Columna
columnas	Array entero largo	Array de los números de columnas de inicio
lineas	Array entero largo	Array de números de líneas de inicio
conversiones	Array entero largo	0 = Tipo original; 1 = Definido para texto
master	Entero largo	Número de tabla primaria
tablas	Array entero largo	Array de los números de tablas
campos	Array entero largo	Array de números de campos

Descripción

El comando PV FIELDS LIST TO CELLS es el mismo que el comando PV FIELD TO CELLS con varios campos.

Nota: el uso del parámetro direccion es diferente del parámetro dirección en los comandos PV GOTO NEXT CELL y PV GET NEXT FREE CELL, donde la direccion puede ser en cualquier sentido. Para PV FIELDS LIST TO CELLS, la direccion es hacia la derecha (0=linea), o hacia la parte inferior (1=columna).

Los parámetros columnas y lineas contienen respectivamente los números de columnas y de líneas de las celdas de inicio.

El quinto parámetro, conversion, permite volver a escribir el contenido de la celda como texto. El tipo de valor fuente debe ser compatible con esta operación: si usted solicita un cambio de tipo un BLOB o de una imagen a texto, conversion se ignorará.

Los arrays tablas y campos contienen los números de tablas y de campos fuentes.

El comando se puede aplicar a las tablas relacionadas o a la tabla master utilizando relaciones. Este último debe ser de tipo automático y pasa de la tabla master a la tabla del campo a mostrar, definido por los arrays tablas y campos.

A diferencia de los comandos de tipo PV ADD DYNAMIC FIELDS, que mantienen una relación dinámica con la base de datos, las modificaciones de valores efectuadas en el área 4D View, después de haber sido recuperados utilizando el comando PV FIELDS LIST TO CELLS no se ejecutan en el contenido de los registros.

Ejemplo

Una vez más utilizamos el ejemplo del comando PV FIELD TO CELLS de una carga del formulario de entrada para un registro de la tabla de clientes. Esta vez, nosotros manejaremos tres campos simultáneamente.

Una relación automática de la tabla primaria de contactos a la tabla de títulos profesionales permite recuperar, en el campo ad hoc este último, la etiqueta del título de cada contacto a partir de su código de título guardado como un entero (campo de inicio de la relación). Vamos a mostrar la tercera columna relevante (columna E, ya que empezamos desde la columna C).

 C_INTEGER($Master) `Número de la tabla primaria

 C_INTEGER($Index) `Índice de bucle

 

 $Master:=Table(->[Contactos]) `Número de la tabla primaria: contactos (para todas las columnas)

 

 ARRAY LONGINT($ArrayColumns;3) `Número de columnas de celda de inicio

 ARRAY LONGINT($ArrayRows;3) `Número de líneas de las celdas de inicio

 ARRAY INTEGER($ConversionArray;3) `0 para tipo original o 1 para definir en texto

 ARRAY INTEGER($TablesArray;3) `Números de tablas

 ARRAY INTEGER($FieldsArray;3) `Números de campos

 

 For($Index;1;3)

    $ArrayColumns{$Index}:=$Index+2 `Columnas C a E

    $ArrayRows{$Index}:=2 `A partir de la segunda línea

    $ConversionArray{$Index}:=0 `Conservamos los tipos de los campos

 End for

 

  `Tablas y campos a recuperar

 $TablesArray{1}:=Table(->[Contactos]) `Número de la tabla de contactos

 $FieldsArray{1}:=Field(->[Contactos]ContactName) `Número del campo Apellido

 

 $TablesArray{2}:=Table(->[Contactos]) `Número de la tabla de contactos

 $FieldsArray{2}:=Field(->[Contactos]ContactFirstName) `Número del campo Nombre

 

 $TablesArray{3}:=Table(->[Titulos]) `Número de la tabla de tipo título (relacionada)

 $FieldsArray{3}:=Field(->[Titulos]Label) `Número del campo Etiqueta (Presidente, Secretario, Desarrollador)

 

  `Recuperación de las selección de contactos correspondiente

 RELATE MANY([Clientes]code)

 

  `Actualización del área 4D View con los campos Nombre, Apellido y Titulo

 PV FIELDS LIST TO CELLS(Area;1;$ArrayColumns;$ArrayRows;$ConversionArray;$Master;

 $TablesArray;$FieldsArray)