4D Doc Center : PV FIELDS LIST TO CELLS

4D View v14

PV FIELDS LIST TO CELLS


PV FIELDS LIST TO CELLS ( area ; endereço ; colunas ; linhas ; conversoes ; master ; tabelas ; campos )

Parâmetro	Tipo	Descrição
area	Inteiro longo	Área 4D View
endereço	Inteiro	0 = Linha; 1 = Coluna
colunas	Array inteiro longo	Array dos números de colunas de início
linhas	Array inteiro longo	Array de números de linhas de início
conversoes	Array inteiro longo	0 = Tipo original; 1 = Definido para texto
master	Inteiro longo	Número de tabela primária
tabelas	Array inteiro longo	Array dos números de tabelas
campos	Array inteiro longo	Array de números de campos

Descrição

O comando PV FIELDS LIST TO CELLS é o mesmo que o comando PV FIELD TO CELLS com vários campos.

Nota: O uso do parâmetro endereço é diferente do parâmetro endereço nos comandos PV GOTO NEXT CELL e PV GET NEXT FREE CELL, onde o endereço pode ser em qualquer sentido. Para PV FIELDS LIST TO CELLS, o endereço é para a direita (0=linha), ou para a parte inferior (1=coluna).

Os parâmetros colunas e linhas contém respectivamente os números de colunas e de linhas das células de início.

O quinto parâmetro, conversao, permite voltar a escrever o conteúdo da célula como texto. O tipo de valor fonte deve ser compatível com esta operação: se você solicita uma mudança de tipo BLOB ou de uma imagem a texto, conversao será ignorado.

Os arrays tabelas e campos contém os números de tabelas e de campos fontes.

O comando pode aplicar as tabelas relacionadas ou a tabela master utilizando relações. Este último deve ser de tipo automático e passa da tabela master a tabela do campo a mostrar, definido pelos arrays tabelas e campos.

A diferença dos comandos de tipo PV ADD DYNAMIC FIELDS, que mantém uma relação dinâmica com o banco de dados, as modificações de valores realizadas na área 4D View, depois de ter sido recuperadas utilizando o comando PV FIELDS LIST TO CELLS não se executam no conteúdo dos registros.

Exemplo

Uma vez mais utilizamos o exemplo do comando PV FIELD TO CELLS de uma carga do formulário de entrada para um registro da tabela de clientes. Esta vez, nós vamos lidar com três campos simultaneamente.

Uma relação automática da tabela primária de contatos a tabela de títulos profissionais permite recuperar, no campo ad hoc este último, a etiqueta do título de cada contato a partir de seu código de título guardado como um inteiro (campo de início da relação). Vamos mostrar a terceira coluna relevante (coluna E, já que começamos desde a coluna C).

 C_INTEGER($Master) `Número da tabela primária

 C_INTEGER($Index) `Índice de laço

 

 $Master:=Table(->[Contatos]) `Número da tabela primária: contatos (para todas as colunas)

 

 ARRAY LONGINT($ArrayColumns;3) `Número de colunas de célula de início

 ARRAY LONGINT($ArrayRows;3) `Número de linhas das células de início

 ARRAY INTEGER($ConversionArray;3) `0 para tipo original ou 1 para definir em texto

 ARRAY INTEGER($TablesArray;3) `Números de tabelas

 ARRAY INTEGER($FieldsArray;3) `Números de campos

 

 For($Index;1;3)

    $ArrayColumns{$Index}:=$Index+2 `Columnas C a E

    $ArrayRows{$Index}:=2 `A partir da segunda linha

    $ConversionArray{$Index}:=0 `Conservamos os tipos dos campos

 End for

 

  `Tabelas e campos a recuperar

 $TablesArray{1}:=Table(->[Contatos]) `Número da tabela de contatos

 $FieldsArray{1}:=Field(->[Contatos]ContactName) `Número do campo Sobrenome

 

 $TablesArray{2}:=Table(->[Contatos]) `Número da tabela de contatos

 $FieldsArray{2}:=Field(->[Contatos]ContactFirstName) `Número do campo Nome

 

 $TablesArray{3}:=Table(->[Títulos]) `Número da tabela de tipo título (relacionada)

 $FieldsArray{3}:=Field(->[Títulos]Label) `Número do campo Etiqueta (Presidente, Secretário, Programador)

 

  `Recuperação das seleções de contatos correspondentes

 RELATE MANY([Clientes]code)

 

  `Atualização da área 4D View com os campos Nome, Sobrenome e Título

 PV FIELDS LIST TO CELLS(Area;1;$ArrayColumns;$ArrayRows;$ConversionArray;$Master;

 $TablesArray;$FieldsArray)