4D Doc Center : PV SET CELL CONTROL

4D View v14

PV SET CELL CONTROL


PV SET CELL CONTROL ( area ; coluna ; linha ; tipo ; nomeVar ; metodo ; titulo )

Parâmetro	Tipo	Descrição
area	Inteiro longo	Área 4D View
coluna	Inteiro longo	Número de coluna da célula
linha	Inteiro longo	Número de linha da célula
tipo	Inteiro	Tipo de controle
nomeVar	cadeia	Nome da variável de gestão de controle
metodo	cadeia	Nome do método de chamada
titulo	cadeia	Título do controle

Descrição

O comando PV SET CELL CONTROL coloca um "controle" na célula designada por linha e coluna.
Um controle é um objeto de tipo botão, caixa de seleção, botão de rádio, lista deslocável ou um combo box dentro de uma célula.
Se um controle já foi inserido na célula, se elimina e se substitui pelo novo controle, qualquer que seja seu tipo.

tipo indica o tipo de controle (entre os cinco mencionados anteriormente) que figura na célula. Para definir este parâmetro, utilize as constantes do tema PV Controles.

nomVar é a variável associada ao controle. Passe o nome do array que contém os valores a mostrar (para os controles de tipos lista deslocável e combo box).

metodo contém o nome do método de chamada relacionado com o controle. Para mais informação sobre os métodos de chamada, consulte a seção PV Área, Introdução.

titulo contém a etiqueta do botão, caixa de seleção, etc.

Exemplo

Os seguintes métodos permitem visualizar os diferentes tipos de controles:

Botão padrão em C3:

 C_LONGINT(vStandardButton) `Botão padrão

 PV SET CELL CONTROL(Area;3;3;pv control push button;"vStandardButton";"CallbackButton";"Button")

 

  `Método CallbackButton

 C_LONGINT($1) `Área 4D View

 C_LONGINT($2) `Número de coluna

 C_LONGINT($3) `Número de linha

 C_POINTER($4) `Ponteiro ao objeto de chamada

 ALERT("Control from method: "+Current method name)

Botões rádio em E3, E4, E5:

 C_LONGINT(vRadio1;vRadio2;vRadio3) `Botões rádio

 vRadio1:=1

 vRadio2:=0

 vRadio3:=0

 PV SET CELL CONTROL(Area;5;3;pv control radio button;"vRadio1";"CallbackRadio";"Dia")

 PV SET CELL CONTROL(Area;5;4;pv control radio button;"vRadio2";"CallbackRadio";"Mês")

 PV SET CELL CONTROL(Area;5;5;pv control radio button;"vRadio3";"CallbackRadio";"Ano")

 

  `Método CallbackRadio

 C_LONGINT($1) `Área 4D View

 C_LONGINT($2) `Número de coluna

 C_LONGINT($3) `Número de linha

 C_POINTER($4) `Ponteiro ao objeto de chamada

 C_STRING(6;$Value)

 Case of

    :($4=(->vRadio1))

       vRadio2:=0

       vRadio3:=0

       $Value:="Dia"

    :($4=(->vRadio2))

       vRadio1:=0

       vRadio3:=0

       $Value:="Mês"

    :($4=(->vRadio3))

       vRadio1:=0

       vRadio2:=0

       $Value:="Ano"

 End case

 PV SET CELL TEXT VALUE($1;($2+1);3;$Value)

Caixas de seleção em E7, E8, E9:

 C_LONGINT(vCheckBox1;vCheckBox2;vCheckBox3) `Caixas a selecionar

 vCheckBox1:=0

 vCheckBox2:=0

 vCheckBox3:=0

 PV SET CELL CONTROL(Area;5;7;pv control check box;"vCheckBox1";"CallbackCheckBox";"Principiante")

 PV SET CELL CONTROL(Area;5;8;pv control check box;"vCheckBox2";"CallbackCheckBox";"Intermédio")

 PV SET CELL CONTROL(Area;5;9;pv control check box;"vCheckBox3";"CallbackCheckBox";"Experto")

 

  `Método CallbackCheckBox

 C_LONGINT($1) `Área 4D View

 C_LONGINT($2) `Número de coluna

 C_LONGINT($3) `Número de linha

 C_POINTER($4) `Ponteiro ao objeto de chamada

 C_TEXT($Value)

 If(vCheckBox1=1)

    $Value:="Principiante"

 End if

 If(vCheckBox2=1)

    If($Value#"")

       $Value:=$Value+" + "

    End if

    $Value:=$Value+"Intermédio"

 End if

 If(vCheckBox3=1)

    If($Value#"")

       $Value:=$Value+" + "

    End if

    $Value:=$Value+"Expert"

 End if

 PV SET CELL TEXT VALUE($1;($2+1);7;$Value)

Lista deslocada em C5:

 ARRAY TEXT(DropdownListArray;5) `Para lista deslocável

 DropdownListArray{1}:="Segunda"

 DropdownListArray{2}:="Terça"

 DropdownListArray{3}:="Quarta"

 DropdownListArray{4}:="Quinta"

 DropdownListArray{5}:="Sexta"

 DropdownListArray:=3 `Padrão a quarta

 PV SET CELL CONTROL(Area;3;5;pv control drop down;"DropdownListArray";"CallbackDropList";"")

 

  `Método CallbackDropList

 C_LONGINT($1) `Área 4D View

 C_LONGINT($2) `Número de coluna

 C_LONGINT($3) `Número de linha

 C_POINTER($4) `Ponteiro ao objeto de chamada

 PV SET CELL TEXT VALUE($1;3;6;DropdownListArray{DropdownListArray})

Combo box em C7:

 ARRAY TEXT(ComboArray;5) `Para lista do combo box

 ComboArray{1}:="Segunda"

 ComboArray{2}:="Terça"

 ComboArray{3}:="Quarta"

 ComboArray{4}:="Quinta"

 ComboArray{5}:="Sexta"

 ComboArray:=5 `Padrão para sexta

 PV SET CELL CONTROL(Area;3;7;pv control combo box;"ComboArray";"CallbackCombo";"")

 

  `Método: CallbackCombo

 C_LONGINT($1) `Área 4D View

 C_LONGINT($2) `Número de coluna

 C_LONGINT($3) `Número de linha

 C_POINTER($4) `Ponteiro ao objeto de chamada

 PV SET CELL TEXT VALUE($1;3;8;ComboArray{0})