Utilizar el elemento cero de un array

4D v20.1

Un array siempre tiene un elemento cero. Mientras el elemento cero no se muestra cuando un array maneja un objeto de formulario, no hay restricción(*) en utilizarlo con el lenguaje.

Un ejemplo del uso del elemento cero es el caso del combo box de la sección Arrays y objetos de formulario.

Otros ejemplo: si quiere ejecutar una acción sólo cuando haga clic en un elemento diferente del previamente seleccionado, debe hacer seguimiento de cada elemento seleccionado. Una manera de hacer esto es utilizar una variable de proceso en la cual usted mantiene el número del elemento seleccionado. Otra forma es utilizar el elemento cero del array:

  ` Método de objeto área de desplazamiento atNombres

 Case of

    :(Form event code=On Load)

  ` Inicialización del array (como se mostró anteriormente)

       ARRAY TEXT(atNames;5)

  ` ...

  ` Inicializar el elemento cero con el número

  ` de elemento actual seleccionado en su forma alfanúmerica

  ` Acá comienza sin elemento seleccionado

       atNames{0}:="0"

 

    :(Form event code=On Unload)

  ` Ya no necesitamos el array

       CLEAR VARIABLE(atNames)

 

    :(Form event code=On Clicked)

       If(atNames#0)

          If(atNames#Num(atNames{0}))

             vtInfo:="Usted hizo clic en: "+atNames{atNames}+" y no fue seleccionado anteriormente."

             atNames{0}:=String(atNames)

          End if

       End if

    :(Form event code=On Double Clicked)

       If(atNames#0)

          ALERT("Usted hizo doble clic en: "+atNames{atNames}

       End if

 End case

(*) Sin embargo, hay una excepción: en los List Box de tipo array, el elemento cero se utiliza internamente para guardar el valor anterior de un elemento en edición, de manera que no es posible utilizarlo en este contexto particular.

Ver también

Arrays