Utiliser l'élément zéro d'un tableau

4D v20.1

Un tableau a toujours un élément zéro. Même si l'élément zéro n'est pas affiché lorsqu'un tableau est utilisé pour remplir un objet de formulaire, vous pouvez l'utiliser sans réserve(*) dans le langage.

Un exemple possible d'utilisation de l'élément zéro est le cas de la combo box examiné dans la section Tableaux et objets de formulaire.

Voici un autre exemple : vous voulez exécuter une action seulement lorsque vous cliquez sur un élément autre que l'élément préalablement sélectionné. Pour cela, vous devez garder la trace de chaque élément sélectionné. Une façon de le faire est d'utiliser une variable process dans laquelle vous conservez le numéro de l'élément sélectionné. Une autre manière consiste à utiliser l'élément zéro du tableau :

  ` Méthode objet zone de défilement atNoms

 Au cas ou

    :(Evenement formulaire code=Sur chargement)

  ` Initialisont le tableau

       TABLEAU TEXTE(atNoms;5)

  ` ...

  ` Initialiser l'élément zéro avec le numéro

  ` de l'élément courant sélectionné sous sa forme alphanumérique

  ` Ici vous commencez sans élément sélectionné

       atNoms{0}:="0"

 

    :(Evenement formulaire code=Sur libération)

  ` Nous n'avons plus besoin du tableau

       EFFACER VARIABLE(atNoms)

 

    :(Evenement formulaire code=Sur clic)

       Si(atNoms#0)

          Si(atNoms#Num(atNoms{0}))

             vtInfo:="Vous avez cliqué sur : "+atNoms{atNoms}+" qui n'était pas précédemment sélectionné."

             atNoms{0}:=Chaine(atNoms)

          Fin de si

       Fin de si

    :(Evenement formulaire code=Sur double clic)

       Si(atNoms#0)

          ALERTE("Vous avez double-cliqué sur : "+atNoms{atNoms})

       Fin de si

 Fin de cas

(*) Il existe une exception : dans les List Box de type tableau, l'élément zéro est utilisé en interne pour conserver la valeur précédente d'un élément en cours d'édition. Il n'est donc pas possible de l'utiliser dans ce contexte.

Voir aussi

Présentation des tableaux