entitySelection.refresh( )

4D v19

説明

注: このメソッドはリモートデータストア(クライアント/サーバーモード、またはOpen datastore 接続)においてのみ動作します。

entitySelection.refresh( ) メソッドはローカルのORDA キャッシュにあるエンティティセレクションデータを即座に"無効化"します。そのため、4D が次にエンティティセレクションを必要としたときにはそれがデータベースからリロードされます。

デフォルトでは、ローカルのORDAのキャッシュは30秒後に無効化されます。クライアント/サーバーモードのアプリケーションのコンテキストにおいてORDA とクラシック言語の両方を使用している場合、このメソッドを使用することでリモートアプリケーションが必ず最新のデータを使用するようにすることができます。

例題 1

ここでは、クラシック言語とORDA言語の両方が、同じデータを同時に編集する場合を考えます:

  // リモートの4D上で実行

 

 C_OBJECT($selection;$student)

 

 $selection:=ds.Students.query("lastname=:1";"Collins")

  // 最初のエンティティをORDA のキャッシュに読み込む

 $student:=$selection.first()

 

  // 4Dのクラシック言語でデータを更新する。ORDA キャッシュはこのことは知らない

 QUERY([Students];[Students]lastname="Collins")

 [Students]lastname:="Colin"

 SAVE RECORD([Students])

 

  // 最新のバージョンを取得するため、ORDA キャッシュを一度無効化する必要がある

 $selection.refresh()

  // キャッシュが失効していなくても、最初のエンティティはディスクから再読み込みされる

 $student:=$selection.first()

 

  //$student.lastname には"Colin"が格納されている

例題 2

リストボックスにForm.students エンティティセレクションを表示し、複数のクライアントがそれを操作する場合を考えます。

  // フォームメソッド:

 Case of

    :(Form event code=On Load)

       Form.students:=ds.Students.all()

 End case

  //

  //

  // クライアント#1にて、ユーザーが最初のエンティティをロードし、更新して保存した

  // 次にクライアント#2にて、ユーザーが同じエンティティをロードし、更新して保存した

  //

  //

  // クライアント#1において:

 Form.students.refresh() // Form.students エンティティセレクションのORDA キャッシュを無効化する

  // リストボックスの中身はデータベースの内容で更新され、クライアント#2が行った変更も反映される