New object

Home

4D v19

New object


New object {( Eigenschaft ; Wert {; Eigenschaft2 ; Wert2 ; ... ; EigenschaftN ; WertN} )} -> Funktionsergebnis

Parameter	Typ	Beschreibung
Eigenschaft	Text	Name der anzulegenden Eigenschaft
Wert	Text, Datum, Boolean, Zeiger, Zahl, Objekt	Wert der Eigenschaft
Funktionsergebnis	Objekt	Neues Objekt der Programmiersprache

Beschreibung

Die Funktion New object erstellt ein neues leeres oder vorab gefülltes Objekt und gibt seine Referenz zurück.

Übergeben Sie keine Parameter, erstellt New object ein leeres Objekt und gibt seine Referenz zurück. Sie müssen diese Referenz einer 4D Variablen übergeben, die mit C_OBJECT oder über ein 4D Objektfeld deklariert ist.

Hinweis: C_OBJECT deklariert eine Variable vom Typ Objekt, erstellt aber kein Objekt.

Optional können Sie das neue Objekt vorab füllen, indem Sie ein oder mehrere Eigenschaft/Wert Paare als Parameter übergeben:

Im Parameter Eigenschaft übergeben Sie die Bezeichnung der zu erstellenden Eigenschaft. Beachten Sie, dass dieser Parameter zwischen Groß- und Kleinschreibung unterscheidet.
Im Parameter Wert übergeben Sie den Wert, den Sie für die Eigenschaft setzen wollen. Es werden verschiedene Datentypen unterstützt. Es gilt folgendes:
- ein Zeiger wird unverändert beibehalten; er wird über die Funktion JSON Stringify bewertet,
- Datumsangaben werden als Datumsformat "yyyy-mm-dd" oder als Zeichenkette "YYYY-MM-DDTHH:mm:ss.SSSZ" gespeichert, gemäß der aktuellen Datenbank-Eigenschaft für Datum innerhalb von Objekten (siehe Seite Kompatibilität). Werden 4D Datumsangaben vor dem Speichern im Objekt in Text umgewandelt, berücksichtigt das Programm standardmäßig die lokale Zeitzone. Dieses Verhalten können Sie über den Selektor Dates inside objects des Befehls SET DATABASE PARAMETER ändern.
- eine Zeitangabe wird als Anzahl in Millisekunden gespeichert (Zahl).

Beispiel 1

Dieser Code kann leere oder gefüllte Objekte erstellen:

 C_OBJECT($obj1)

 C_OBJECT($obj2)

 C_OBJECT($obj3)

 $obj1:=New object

  // $obj1 = {}

 $obj2:=New object("name";"Smith")

  // $obj2 = {name:Smith}

 $obj3:=New object("name";"Smith";"age";40)

  // $obj3 = {name:Smith,age:40}

Beispiel 2

Ein neues Objekt mit einem Objekt als Parameter Wert erstellen:

 C_OBJECT($Children;$Contact)

 

  //Ein Objekt Array erstellen

 ARRAY TEXT($arrChildren;3)

 $arrChildren{1}:="Richard"

 $arrChildren{2}:="Susan"

 $arrChildren{3}:="James"

 OB SET ARRAY($Children;"Children";$arrChildren)

 

  //Das Objekt initialisieren

 $Contact:=New object("FirstName";"Alan";"LastName";"Parker";"age";30;"Children";$Children)

  // $Contact = {FirstName:Alan,LastName:Parker,age:30,Children:{Children:[Richard,Susan,James]}}

Beispiel 3

Dieser Code übergibt Objekte als Parameter:

 C_OBJECT($measures)

 $measures:=Get database measures(New object("path";"DB.cacheReadBytes";"withHistory";True;"historyLength";120))

Beispiel 4

Mit diesem Code können Sie Objekte in Schleifen einfach verwalten:

 ARRAY OBJECT($refs;0)

 C_LONGINT(vCounter)

 

 For(vCounter;1;100)

    APPEND TO ARRAY($refs;New object("line";"Line number "+String(vCounter)))

 End for

Siehe auch

New shared object