SVG_New_text

4D v18

SVG_New_text


SVG_New_text ( parentSVGObject ; text {; x {; y {; font \| styleDef {; size {; style {; alignment {; color {; rotation {; lineSpacing {; stretching}}}}}}}}}} ) -> 戻り値

引数	型	説明
parentSVGObject	SVG_Ref	親要素の参照
text	テキスト	挿入するテキスト
x	実数	X軸の座標
y	実数	Y軸の座標
font \| styleDef	テキスト	フォント名またはスタイル定義
size	倍長整数	文字サイズのポイント数
style	倍長整数	文字スタイル
alignment	倍長整数	行揃え
color	文字	テキストカラー
rotation	実数	テキストの回転角度
lineSpacing	実数	行間隔のポイント数
stretching	実数	水平ストレッチファクター
戻り値	SVG_Ref	SVGテキストオブジェクト参照

説明

SVG_New_text コマンドはparentSVGObject 引数で指定されたSVGコンテナ内にテキストを挿入し、その参照を返します。parentSVGObject 引数がSVGドキュメント出ない場合には、エラーが生成されます。

注: 4D v15以降、SVG_New_text コマンドはシンプルなスタイル付きテキストをサポートするようになりました(テキストは異なるスタイルを含むことができますが、SPANタグをネストすることはできません)。例題5を参照して下さい。

任意のx と y 引数を使用するとテキストの最初の文字の上端のX軸とY軸の座標を指定することができます。この点は、行揃えの値に応じて扱われ方が異なってきます。左揃えの場合にはこの点は文字列の左端として扱われ、右揃えの場合にはこの点は文字列の右端として扱われます。中央揃えの場合にはこの点が中央として扱われます。

SVG_New_text コマンドは二つの異なる文字設定のシンタックスを受け付けます:

font、size、style と alignment 引数に対して様々な値を渡す事ができます:font と size 引数を使用するとフォントとサイズをポイント単位で指定できます。これらの引数が省略された場合、テキストはでTimes New Roman 12 pts で描画されます。
任意のstyle 引数は使用される文字スタイルに関する情報を渡します。style 引数には、以下の値のどれか一つ、または値同士の組み合わせを渡す必要があります(または、4D定数のFont Styles テーマから、それぞれのスタイルに対応する値を使用することもできます):
0 = 標準
1 = 太字
2 = 斜字
4 = 下線付き
8 = 打消し線付き
任意のalignment 引数を使用すると描画されたテキストに対して適用する行揃えのタイプを指定する事ができます。渡す事ができる値は以下の通りです:
2 = 左揃え
3 = 中央揃え
4 = 右揃え

任意のcolor 引数はフォントカラーを受け付けます(カラーに関する詳細については、カラー&グラデーションの章を参照して下さい)。
任意のrotation 引数を使用するとテキストに適用する回転を指定することができます。
任意のlineSpacing 引数を使用するとテキストが複数行にまたがった際の行間隔を指定する事ができます。デフォルトの値は1です。
任意のstretching 引数を使用するとテキストの水平方向の拡大(値>1)または縮小(0から1の間の値)をしていすることができます。
または、(font 引数の代わりに)styleDef 引数にスタイル定義を渡し、それに続く引数を省略することもできます。例えば、以下の様に指定する事ができます。:
SVG_New_textArea($Dom_svg;"Hello World !";x;y;vWidth;vHeight;style_definition)

... ここではstyle_definition 引数には完全なスタイル定義が含まれています。例えば、"{font-size:48px;fill:red;}"を渡した場合、この定義はスタイル属性としてフォームに追加されます:
```
style="font-size:48px;fill:red;"
```
この場合、これ以外の引数は全て無視されます。

例題 1

デフォルトのテキストプロパティを使用したシンプルなテキスト:

 $SVG:=SVG_New

 $textID:=SVG_New_text($SVG;"Hello world!")

例題 2

青い、斜字で下線付きの右揃えのテキスト:

 $SVG:=SVG_New

 $text:="Hello world!\rBonjour le monde!\rHola Mundo!"

 $size:=48

 $font:="helvetica"

 $textID:=SVG_New_text($SVG;$text;400;10;$font;$size;Italic+Underline;Align right;"blue")

例題 3

垂直なテキスト:

 $SVG:=SVG_New

 $textID:=SVG_New_text($SVG;$text;-250;0;"";48;-1;-1;"red";-90)

例題 4

縮小、または拡大されたテキスト:

 $SVG:=SVG_New

 $textID:=SVG_New_text($SVG;"Hello world (condensed)";0;0;"";-1;-1;-1;"blue";0;1;0,8)

 $textID:=SVG_New_text($SVG;"Hello world (normal)";0;24)

 $textID:=SVG_New_text($SVG;"Hello world (stretched)";0;48;"";-1;-1;-1;"red";0;1;2)

例題 5

マルチスタイルテキストの表示:

 C_TEXT($Dom_svg;$Dom_text;$Txt_buffer)

  //マルチスタイルテキストを定義

 $Txt_buffer:="<SPAN STYLE=\"font-size:18pt\">Hello </SPAN>"+\

 "<SPAN STYLE=\"font-size:24pt;font-weight:bold;color:#D81E05\">World</SPAN>"+\

 "<SPAN STYLE=\"font-size:36pt\">!</SPAN><BR/>"+\

 "<SPAN STYLE=\"font-size:19pt;font-style:italic\">It's </SPAN>"+\

 "<SPAN STYLE=\"font-size:24pt\">Monday</SPAN>"

 $Dom_svg:=SVG_New

 

  //タイトル

 SVG_SET_FONT_COLOR(SVG_New_text($Dom_svg;"_______ svg_Newtext _______";10;30);"blue")

  //テキスト

 $Dom_text:=SVG_New_text($Dom_svg;$Txt_buffer;50;50)

 

 SVGTool_SHOW_IN_VIEWER($Dom_svg)

 SVG_CLEAR($Dom_svg)

参照

SVG_New_textArea
SVG_New_tspan
SVG_New_vertical_text