4D v15
Utiliser la clause WHERE
- 4D - Référence SQL
-
- Prise en main
-
- Introduction
- Recevoir le résultat d'une requête SQL dans une variable
- Utiliser la clause WHERE
- Recevoir le résultat d'une requête SQL dans un tableau
- Utiliser la fonction CAST
- Utiliser la clause ORDER BY
- Utiliser la clause GROUP BY
- Utiliser des fonctions statistiques
- Utiliser la clause HAVING
- Appeler des méthodes 4D depuis le code SQL
- Jointures
- Utiliser des alias
- Sous-requêtes
- Tracer et déboguer le code SQL
- Data Definition Language
- Connexions externes
- Connexion au moteur SQL 4D via le driver ODBC
4D v15
Utiliser la clause WHERE
Utiliser la clause WHERE
Nous souhaitons à présent savoir combien de films réalisés à partir de 1960 sont présents dans la base. Voici le code 4D correspondant à cette requête :
C_ENTIER LONG($NoMovies)
$NoMovies:=0
REDUIRE SELECTION([MOVIES];0)
CHERCHER([MOVIES];[MOVIES]Year_of_Movie>=1960)
$NoMovies:=Enregistrements trouves([MOVIES])
ALERTE("La videothèque contient "+Chaine($NoMovies)+" films réalisés depuis 1960")- En utilisant du code SQL :
C_ENTIER LONG($NoMovies)
$NoMovies:=0
REDUIRE SELECTION([MOVIES];0)
Debut SQL
SELECT COUNT(*)
FROM MOVIES
WHERE Year_of_Movie >= 1960
INTO :$NoMovies;
Fin SQL
ALERTE("La videothèque contient "+Chaine($NoMovies)+" films réalisés depuis 1960")
- En utilisant les commandes SQL génériques :
C_ENTIER LONG($NoMovies)
$NoMovies:=0
REDUIRE SELECTION([MOVIES];0)
SQL LOGIN(SQL_INTERNAL;"";"")
SQL EXECUTER("SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960";$NoMovies)
SQL CHARGER ENREGISTREMENT(SQL tous les enregistrements)
SQL LOGOUT
ALERTE("La videothèque contient "+Chaine($NoMovies)+" films réalisés depuis 1960")
- En utilisant la commande 4D CHERCHER PAR SQL :
C_ENTIER LONG($NoMovies)
$NoMovies:=0
REDUIRE SELECTION([MOVIES];0)
CHERCHER PAR SQL([MOVIES];"Year_of_Movie >= 1960")
$NoMovies:=Enregistrements trouves([MOVIES])
ALERTE("La videothèque contient "+Chaine($NoMovies)+" films réalisés depuis 1960")
- En utilisant la commande SQL dynamique EXECUTE IMMEDIATE :
C_ENTIER LONG($NoMovies)
C_TEXTE($tQueryTxt)
$NoMovies:=0
REDUIRE SELECTION([MOVIES];0)
$tQueryTxt:="SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960 INTO :$NoMovies;"
Debut SQL
EXECUTE IMMEDIATE :$tQueryTxt;
Fin SQL
ALERTE("La videothèque contient "+Chaine($NoMovies)+" films réalisés depuis 1960")
Comme dans la section précédente, pour tester tous ces exemples, lancez la base "4D SQL Code Samples" et affichez la boîte de dialogue principale. Choisissez le mode d'interrogation du moteur de 4D et cliquez sur le bouton Clause WHERE.
PROPRIÉTÉS
Produit : 4D
Thème : Prise en main
Nom intl. : Using the WHERE clause
HISTORIQUE
UTILISATION DE L'ARTICLE
4D - Référence SQL ( 4D v15)
© 1985-2017 4D SAS / 4D, Inc. Tous droits réservés.