Command name

4D v15.4

Command name


Command name ( command ) -> 戻り値

引数	型	説明
command	倍長整数	コマンド番号
戻り値	文字	ローカライズされたコマンド名

互換性に関する注意

このコマンドの有用性は、4Dの以下のような進化に伴い大幅に減少してきました:

トークナイズドされていない宣言(フォーミュラ)に対して、4Dではトークンシンタックスというものを提供しています。これを使用するとコマンド名の変化による問題が起こる可能性を避けることができる一方、これらの名前を読みやすいマナーで入力する事ができます。このシンタックスは他のランゲージ要素、例えばテーブルやフィールドなどに対しても使用する事ができます。この点についてのより詳細な情報については、フォーミュラ内でのトークンの使用の章を参照して下さい。
4D v15以降、全ての言語の4Dにおいて、英語版のプログラミング言語がデフォルトで使用されるようになりました。それにより、データベースのローカライズに関係するこのコマンドの需要は減少しました。

説明

Command name コマンドは、引数commandに渡したコマンド番号のコマンド名を返します。

このコマンド名は、4Dのバージョンによって異なる場合(コマンドの改名)や、アプリケーション言語によって異なる場合(*)もあります。

(*) 4D v15以降、アプリケーション言語はデフォルトで英語が使用されるようになりました。とはいえ、データベース設定のメソッドページの"リージョンシステム設定を使用"オプションを使用する事で、フランス語版の4Dにおいてフランス語を使用する事ができます。

注: コマンド毎のコマンド番号は、コマンドドキュメントのプロパティエリアに書かれています。

Command name コマンドはcommand 変数の番号がが既存のコマンド番号に対応する場合にはOK 変数が1に設定され、それ以外の場合には0が設定されます。しかしながら、既存のコマンドの一部には無効化されてしまったコマンドもあり、そういったコマンドの場合にはCommand name は空の文字列を返すという点に注意が必要です(最後の例題を参照して下さい)。

例題 1

フォームで、一般的なサマリーレポートコマンドのドロップダウンリストを作成します。ドロップダウンリストのオブジェクトメソッドに、次のように記述します:

 Case of

    :(Form event=On Before)

       ARRAY TEXT(asCommand;4)

       asCommand{1}:=Command name(1)

       asCommand{2}:=Command name(2)

       asCommand{3}:=Command name(4)

       asCommand{4}:=Command name(3)

  ` ...

 End case

4Dの日本語版ではドロップダウンリストに、Sum、Average、Min、Maxが表示されます。フランス語版*では、ドロップダウンリストには、Somme、Moyenne、Min、Maxが表示されます。

*フランス語のプログラミング言語を使用するよう設定されている4Dアプリケーション(互換性に関する注意を参照して下さい)

例題 2

以下のコードを使用すると、全ての有効な4Dコマンドを配列内に読み込むことができます:

 C_LONGINT($Lon_id)

 C_TEXT($Txt_command)

 ARRAY LONGINT($tLon_Command_IDs;0)

 ARRAY TEXT($tTxt_commands;0)

 

 Repeat

    $Lon_id:=$Lon_id+1

    $Txt_command:=Command name($Lon_id)

    If(OK=1) // コマンド番号が存在する

       If(Length($Txt_command)>0) // コマンドが無効化されていない

          APPEND TO ARRAY($tTxt_commands;$Txt_command)

          APPEND TO ARRAY($tLon_Command_IDs;$Lon_id)

       End if

    End if

 Until(OK=0) //既存のコマンドの終わり

参照

EXECUTE FORMULA