Command name

4D v15.4

Command name


Command name ( commande ) -> Résultat

Paramètre	Type	Description
commande	Entier long	Numéro de la commande
Résultat	Chaîne	Nom (anglais) de la commande

Note de compatibilité

L'utilité de cette commande a été fortement diminuée au fil des évolutions de 4D :

Pour les instructions non tokenisées (formules), 4D propose une syntaxe tokenisée permettant de s'affranchir des variations des noms de commandes mais aussi des autres éléments comme les tables, tout en permettant de les saisir de façon lisible (pour plus d'informations sur ce point, reportez-vous à la section Utiliser des tokens dans les formules).
A compter de 4D v15, la version anglaise du langage de programmation est utilisée par défaut dans toutes les langues de 4D, réduisant les besoins liés à la localisation des bases.

Description

La fonction Command name retourne le nom de la commande dont le numéro a été passé dans commande.

Ce nom peut varier au fil des versions de 4D (commandes renommées) ou en fonction de la langue de l'application(*).

(*) Par défaut la version anglaise du langage est utilisée à compter de 4D v15, toutefois l'option "Utiliser langage français et paramètres régionaux système" de la Page Méthodes des Préférences permet de continuer à utiliser la version française dans un 4D français.

Note : Le numéro de chaque commande est fourni dans la zone Propriétés de cette documentation.

La commande Command name met la variable OK à 1 si la commande correspond à un numéro de commande existant, et à 0 dans le cas contraire. A noter cependant que certaines commandes existantes ont été désactivées, auquel cas Command name retourne une chaîne vide (cf. dernier exemple).

Exemple 1

Dans un formulaire, vous voulez afficher une liste déroulante contenant les commandes standard de génération d'états. Dans la méthode objet de cette liste déroulante, vous écrivez :

 Case of

    :(Form event=On Load)

       ARRAY TEXT(asCommand;4)

       asCommand{1}:=Command name(1)

       asCommand{2}:=Command name(2)

       asCommand{3}:=Command name(3)

       asCommand{4}:=Command name(4)

  ` ...

 End case

Dans une version anglaise de 4D, la liste déroulante contiendra : Sum, Average, Min et Max.
Dans une version française* de 4D, la liste déroulante contiendra : Somme, Moyenne, Min et Max.

*avec l'application 4D paramétrée pour utiliser le langage français (cf. note de compatibilité),

Exemple 2

Le code suivant vous permet de charger toutes les commandes 4D valides dans un tableau :

 C_LONGINT($Lon_id)

 C_TEXT($Txt_command)

 ARRAY LONGINT($tLon_Command_IDs;0)

 ARRAY TEXT($tTxt_commands;0)

 

 Repeat

    $Lon_id:=$Lon_id+1

    $Txt_command:=Command name($Lon_id)

    If(OK=1) //le numéro de commande existe

       If(Length($Txt_command)>0) //la commande n'est pas désactivée

          APPEND TO ARRAY($tTxt_commands;$Txt_command)

          APPEND TO ARRAY($tLon_Command_IDs;$Lon_id)

       End if

    End if

 Until(OK=0) //fin des commandes existantes

Voir aussi

EXECUTE FORMULA