Command name

4D v15.4

Command name


Command name ( comando ) -> Resultado

Parámetro	Tipo	Descripción
comando	Entero largo	Número del comando
Resultado	Cadena	Nombre del comando traducido

Nota de compatibilidad

La utilidad de este comando ha disminuido con la evolución de 4D:

Para las instrucciones no tokenizadas (fórmulas), 4D ofrece una ofrece una sintaxis tokenizada que se puede utilizar para evitar posibles problemas debido a las variaciones en los nombres de comandos, sin dejar de poder digitar estos nombres de forma legible. Esta sintaxis también se puede utilizar para los nombres de otros elementos del lenguaje, tales como tablas o campos. Para más información, consulte Utilizar tokens en fórmulas.
A partir de 4D v15, la versión en inglés del lenguaje de programación se utiliza por defecto en todos los idiomas de 4D, lo que reduce las necesidades relacionadas con las localización de las bases.

Descripción

La función Command name devuelve el nombre del comando cuyo número se pasa en comando.

Este nombre puede variar de una versión 4D a otra (comandos renombrados) o según el lenguaje de la aplicación (*).

(*) Por defecto, la versión en Inglés se utiliza a partir de 4D v15; sin embargo, la opción "Usar configuración del sistema regional" en la Página Métodos de las Preferencias le permite continuar utilizando el francés en una versión francesa de 4D.

Nota: el número de cada comando está en el área de Propiedades de la página de documentación del comando.

El comando Command name define la variable OK en 1 si comando corresponde a un número de comando existente, de lo contrario en 0. Note sin embargo, que algunos comandos existentes se han desactivado, en cuyo caso Command name devuelve una cadena vacía (ver el último ejemplo).

Ejemplo 1

En un formulario, usted quiere mostrar una lista desplegable que contenga los comandos estándar de generación de informes. En el método de objeto de esta lista desplegable, usted escribe:

 Case of

    :(Form event=On Before)

       ARRAY TEXT(asCommand;4)

       asCommand{1}:=Command name(1)

       asCommand{2}:=Command name(2)

       asCommand{3}:=Command name(4)

       asCommand{4}:=Command name(3)

  ` ...

 End case

En la versión inglesa de 4D, la lista desplegable contendrá: Sum, Average, Min, y Max. En la versión francesa* de 4D, la lista desplegable contendrá: Somme, Moyenne, Min, y Max.

*con la aplicación 4D configurada para ser utilizada en idioma francés (ver nota de compatibilidad).

Ejemplo 2

El siguiente código le permite cargar todos los comandos 4D válidos en un array:

 C_LONGINT($Lon_id)

 C_TEXT($Txt_command)

 ARRAY LONGINT($tLon_Command_IDs;0)

 ARRAY TEXT($tTxt_commands;0)

 

 Repeat

    $Lon_id:=$Lon_id+1

    $Txt_command:=Command name($Lon_id)

    If(OK=1) //el número de comando existe

       If(Length($Txt_command)>0) //el comando no está desactivado

          APPEND TO ARRAY($tTxt_commands;$Txt_command)

          APPEND TO ARRAY($tLon_Command_IDs;$Lon_id)

       End if

    End if

 Until(OK=0) //fin de los comandos existentes

Ver también

EXECUTE FORMULA