WP INSERER IMAGE

4D v16

WP INSERER IMAGE


WP INSERER IMAGE ( objPlage ; image ; mode {; miseAJourPlage} )

Paramètre	Type	Description
objPlage	Objet	Plage de sélection
image	Image, Chaîne	Champ ou variable Image, ou chemin d'accès à une image sur le disque
mode	Entier long	Mode d'insertion
miseAJourPlage	Entier long	Mode de mise à jour de la plage de sélection

Description

La commande WP INSERER IMAGE insère image dans la plage de sélection objPlage selon le mode d'insertion spécifié. L'image sera insérée en tant que caractère dans la plage de sélection objPlage.

Dans objPlage, passez une plage de sélection valide de 4D Write Pro. objPlage est une partie d'un document 4D Write Pro : elle peut être créée en utilisant les commandes , WP Lire plage signet ou WP Lire plage.

Dans image, vous pouvez passer :

soit un champ image ou une variable image 4D.
soit une chaîne contenant un chemin d'accès à un fichier image stocké sur disque, en utilisant la syntaxe système.
Si vous utilisez une chaîne, vous pouvez passer soit un chemin d'accès complet, soit un chemin d'accès en relatif par rapport au fichier de structure de la base. Vous pouvez aussi passer un nom de fichier, dans ce cas le fichier doit être situé à côté du fichier de structure de la base. Si vous passez un nom de fichier, vous devez indiquer son extension.

Tous les formats d'image pris en charge par 4D peuvent être utilisés (voir la section Introduction aux images). Vous pouvez obtenir la liste des formats d'image disponibles en utilisant la commande LISTE CODECS IMAGES. Si l'image encapsule plusieurs formats (codecs), 4D Write Pro utilise un seul format pour l'affichage et un autre pour l'impression (s'il est différent) ; les formats les mieux adaptés sont automatiquement sélectionnés.

Dans le paramètre mode, passez une des constantes suivantes pour indiquer le mode d'insertion à utiliser pour insérer l'image dans le document :

Constante	Type	Valeur	Comment
wk append	Entier long	2	Insère le contenu à la fin de la plage
wk prepend	Entier long	1	Le contenu est inséré au début de la plage
wk replace	Entier long	0	Remplace le contenu de la plage

Dans le paramètre optionnel miseAJourPlage, vous pouvez passer une des constantes suivantes pour préciser si l'image est incluse ou non dans la plage de sélection résultante :

Constante	Type	Valeur	Comment
wk exclude from range	Entier long	1	Le contenu inséré n'est pas inclus dans la plage mise à jour
wk include in range	Entier long	0	Le contenu inséré est inclus dans la plage mise à jour (défaut)

Si vous ne passez pas le paramètre miseAJourPlage, par défaut l'image est incluse dans la plage mise à jour.

Exemple

Dans l'exemple suivant, un utilisateur choisit une image qu'il souhaite insérer dans une plage de sélection de l'objet 4D Write Pro, et obtiendra une alerte si l'image ne peut pas être insérée :

 C_OBJET($wpRange)

 $wpRange:=WP Lire selection([Courrier]ZoneWP)

 

 C_BOOLEEN($fail)

 $fail:=Faux

 

   //on demande à l'utilisateur de choisir, sur le disque,l'image qu'il souhaite insérer

 $imgRef:=Ouvrir document("")

   //si l'utilisateur n'annule pas

 Si(OK=1)

         //si le format du fichier image est pris en charge

       Si(Est un fichier image(document))

            // on insère l'image

          WP INSERER IMAGE($wpRange;document;wk replace)

       Sinon

          $fail:=Vrai

       Fin de si

 Sinon

       $fail:=Vrai

 Fin de si

   //si l'insertion a échoué, on informe l'utilisateur

 Si($fail)

       ALERTE("l'insertion de l'image a échoué")

 Fin de si

Voir aussi

WP INSERER DOCUMENT