SVG_New_text

4D v16

SVG_New_text


SVG_New_text ( objetoSVGPai ; texto {; x {; y {; fonte \| defEstilo {; tamanho {; estilo {; alinhamento {; cor {; rotaçao {; espaço {; estiramento }}}}}}}}}} ) -> Resultado

Parâmetro	Tipo	Descrição
objetoSVGPai	Ref_SVG	Referencia do elemento pai
texto	Texto	Texto a inserir
x	Real	Coordenada no eixo X
y	Real	Coordenada no eixo Y
fonte \| defEstilo	Texto	Nome da fonte ou definição de estilo
tamanho	Inteiro longo	Tamanho dos caracteres em pontos
estilo	Inteiro longo	Estilo dos caracteres
alinhamento	Inteiro longo	Alinhamento
cor	String	Cor do texto
rotaçao	Real	Ângulo de rotação do texto
espaço	Real	Espaço entre linhas em pontos
estiramento	Real	Fator de estiramento horizontal
Resultado	Ref_SVG	Referencia do objeto texto SVG

Descrição

O comando SVG_New_text insere o texto no recipiente SVG designado por objetoSVGPai e devolve sua referencia. Se objetoSVGPai não é um documento SVG, é gerado um erro.

Nota: A partir de 4D v15, o comando SVG_New_text é compatível com texto simple Styled (o texto pode conter diferentes estilos, mas atributos SPAN não devem ser aninhados). Ver exemplo 5.

Os parâmetros opcionais x e y permitem especificar a posição no eixo X e Y da esquina superior do primeiro caractere do texto. Este ponto está situado de forma diferente conforme o valor do alinhamento: a esquerda para um alinhamento a esquerda, a direita para um alinhamento a direita ou no centro quando o texto está centrado.

O comando SVG_New_text aceita duas sintaxes diferentes para a definição dos caracteres:

Pode passar diferentes valores nos parâmetros fonte, tamanho, estilo e alinhamento: fonte e tamanho permitem especificar a fonte e o tamanho em pontos a utilizar. Quando não passam estes parâmetros, o texto será escrito em Times New Roman 12 pts.
O parâmetro opcional estilo da o estilo de caracteres a utilizar. Neste parâmetro, deve passar um dos seguintes estilos ou uma combinação de vários de estes valores (ou também pode utilizar as constantes 4D correspondentes no tema Estilos de fonte):
0 = Normal
1 = Negrito
2 = Itálico
4 = Sublinhado
8 = Marcado
O parâmetro opcional alinhamento permite especificar o tipo de alinhamento a aplicar ao texto desenhado. Pode passar um dos seguintes valores:
2 = Alinhado a esquerda
3 = Centrado
4 = Alinhado a direita

O parâmetro opcional cor contém o nome da cor da fonte. (Para mais informação sobre as cores, consulte a seção Cores e gradientes).
O parâmetro opcional rotaçao permite precisar a rotação a aplicar ao texto.
O parâmetro opcional espaço permite especificar o valor do espaço se o texto tem mais de uma linha. Valor por padrão = 1.
O parâmetro opcional estiramento permite aplicar um fator de estiramento horizontal (valor > 1) ou de condensação (valor entre 0 e 1) ao texto.

Ou pode passar uma definição de estilo no parâmetro defEstilo (no lugar do parâmetro fonte) e depois omite os seguintes parâmetros. Por exemplo, pode passar:
SVG_New_textArea($Dom_svg;"Olá mundo";x;y;vWidth;vHeight;style_definition)

... aonde o parâmetro style_definition contém uma definição de estilo completa. Se passar, por exemplo, "{font-size:48px;fill:red;}", esta definição é adicionada como um atributo de estilo desta forma:
```
style="font-size:48px;fill:red;"
```
Neste caso, os parâmetros adicionais são ignorados.

Exemplo 1

Texto simples utilizando as propriedades de texto por padrão:

 $SVG:=SVG_New

 $textID:=SVG_New_text($SVG;"Hello world!")

Exemplo 2

Texto em azul, itálica, sublinhado e alinhado a direita:

 $SVG:=SVG_New

 $text:="Hello world!\rBonjour le monde!\rOlá Mundo!"

 $size:=48

 $font:="helvetica"

 $textID:=SVG_New_text($SVG;$text;400;10;$font;$size;Italic+Underline;Align right;"blue")

Exemplo 3

Texto vertical:

 $SVG:=SVG_New

 $textID:=SVG_New_text($SVG;$text;-250;0;"";48;-1;-1;"red";-90)

Exemplo 4

Texto condensado ou expandido:

 $SVG:=SVG_New

 $textID:=SVG_New_text($SVG;"Hello world (condensed)";0;0;"";-1;-1;-1;"blue";0;1;0,8)

 $textID:=SVG_New_text($SVG;"Hello world (normal)";0;24)

 $textID:=SVG_New_text($SVG;"Hello world (stretched)";0;48;"";-1;-1;-1;"red";0;1;2)

Exemplo 5

Exibe texto multi-estilo:

 C_TEXT($Dom_svg;$Dom_text;$Txt_buffer)

  //definição de texto multi-estilo

 $Txt_buffer:="<SPAN STYLE=\"font-size:18pt\">Hello </SPAN>"+\

 "<SPAN STYLE=\"font-size:24pt;font-weight:bold;color:#D81E05\">World</SPAN>"+\

 "<SPAN STYLE=\"font-size:36pt\">!</SPAN><BR/>"+\

 "<SPAN STYLE=\"font-size:19pt;font-style:italic\">It's </SPAN>"+\

 "<SPAN STYLE=\"font-size:24pt\">Monday</SPAN>"

 $Dom_svg:=SVG_New

 

  //título

 SVG_SET_FONT_COLOR(SVG_New_text($Dom_svg;"_______ svg_Newtext _______";10;30);"blue")

  //texto

 $Dom_text:=SVG_New_text($Dom_svg;$Txt_buffer;50;50)

 

 SVGTool_SHOW_IN_VIEWER($Dom_svg)

 SVG_CLEAR($Dom_svg)

Ver também

SVG_New_textArea
SVG_New_tspan
SVG_New_vertical_text