Import basé sur les procédures stockées (exemple)

4D v16

L'exemple suivant démontre comment l'import de données peut être accéléré de manière spectaculaire en environnement client/serveur. La méthode Import classique listée ci-dessous vous permet de mesurer combien de temps prend un import d'enregistrements basé sur la commande IMPORTER TEXTE :

  ` Méthode projet Import classique

 $vhDocRef:=Open document("")

 If(OK=1)

    CLOSE DOCUMENT($vhDocRef)

    INPUT FORM([Table1];"Import")

    $vhStartTime:=Current time

    IMPORT TEXT([Table1];Document)

    $vhEndTime:=Current time

    ALERT("L'opération a duré "+String(0+($vhEndTime-$vhStartTime))+" secondes.")

 End if

Avec l'import de données classique, 4D analyse le fichier ASCII puis, pour chaque enregistrement, crée un nouvel enregistrement, remplit les champs avec les valeurs importées et envoie l'enregistrement au poste serveur afin qu'il soit ajouté à la base. Par conséquent, de nombreuses requêtes circulent sur le réseau. Afin d'optimiser l'opération, vous pouvez utiliser des procédures stockées pour effectuer l'import localement sur le poste serveur. Le poste client charge le document dans un BLOB et déclenche une procédure stockée en passant le BLOB comme paramètre. La procédure stockée place le BLOB dans un document sur le disque du poste serveur, puis importe le document en local. L'import des données est par conséquent effectué localement à une vitesse comparable à celle d'une version locale de 4D, car la plupart des requêtes transitant sur le réseau ont été éliminées. Voici la méthode projet CLIENT IMPORT. Lancée sur le poste client, elle déclenche l'exécution de la procédure stockée SERVER IMPORT, listée à la suite :

  ` Méthode projet CLIENT IMPORT

  ` CLIENT IMPORT ( Pointeur ; Texte )

  ` CLIENT IMPORT ( -> [Table] ; Formulaire entrée )

 

 C_POINTER($1)

 C_TEXT($2)

 C_TIME($vhDocRef)

 C_BLOB($vxData)

 C_LONGINT(spErrCode)

 

  ` Sélectionnez le document à importer

 $vhDocRef:=Open document("")

 If(OK=1)

  ` Si un document était sélectionné, ne pas le garder ouvert

    CLOSE DOCUMENT($vhDocRef)

    $vhStartTime:=Current time

  ` Essayons de le charger en mémoire

    DOCUMENT TO BLOB(Document;$vxData)

    If(OK=1)

  ` Si le document a pu être chargé dans le BLOB,

  ` Démarrer la procédure stockée qui va importer les données sur le poste serveur

       $spProcessID:=Execute on server("SERVER IMPORT";32*1024;"Serveur Import Services";Table($1);$2;$vxData)

  ` Nous n'avons alors plus besoin du BLOB dans ce process

       CLEAR VARIABLE($vxData)

  ` Attendons l'achèvement de l'opération effectuée par la procédure stockée

       Repeat

          DELAY PROCESS(Current process;300)

          GET PROCESS VARIABLE($spProcessID;spErrCode;spErrCode)

          If(Undefined(spErrCode))

  ` Note: si la procédure stockée n'a pas initialisé sa propre instance

  ` de la variable spErrCode, il se peut qu'une variable indéfinie soit retournée

             spErrCode:=1

          End if

       Until(spErrCode<=0)

  ` Envoyons un accusé de réception à la procédure stockée

       spErrCode:=1

       SET PROCESS VARIABLE($spProcessID;spErrCode;spErrCode)

       $vhEndTime:=Current time

       ALERT("L'opération a duré "+String(0+($vhEndTime-$vhStartTime))+" secondes.")

    Else

       ALERT("Il n'y a pas assez de mémoire pour charger le document.")

    End if

 End if

Voici la méthode projet SERVER IMPORT exécutée en tant que procédure stockée :

  ` Méthode projet SERVER IMPORT

  ` SERVER IMPORT ( Entier long ; Texte ; BLOB )

  ` SERVER IMPORT ( Numéro de table ; Formulaire entrée ; Données importées )

 

 C_LONGINT($1)

 C_TEXT($2)

 C_BLOB($3)

 C_LONGINT(spErrCode)

 

  ` L'opération n'est pas encore terminée, affectons 1 à spErrCode

 spErrCode:=1

 $vpTable:=Table($1)

 INPUT FORM($vpTable->;$2)

 $vsDocName:="Fichier Import "+String(1+Hasard)

 If(Sous Windows)

    $vsDocName:=$vsDocName+".txt" ` Sous Windows, l'extension est obligatoire

 End if

 DELETE DOCUMENT($vsDocName)

 BLOB TO DOCUMENT($vsDocName;$3)

 LECTURE ASCII($vpTable->;$vsDocName)

 DELETE DOCUMENT($vsDocName)

  ` L'opération est terminée, affectons 0 à spErrCode

 spErrCode:=0

  ` Attendons que le poste client à l'origine de la requête ait reçu les résultats

 Repeat

    DELAY PROCESS(Current process;1)

 Until(spErrCode>0)

Note : La méthode projet Sous Windows est fournie dans la section Présentation des documents système du manuel Langage de 4D.

Une fois que ces deux méthodes projet ont été implémentées dans votre base, vous pouvez effectuer un import basé sur une procédure stockée, en écrivant par exemple :

CLIENT IMPORT(->[Table1];"Import")

Si vous réalisez quelques tests comparatifs, vous pourrez constater qu'avec ce type de méthode, l'import des enregistrements est jusqu'à 60 fois plus rapide qu'un import "classique".

Voir aussi

Procédures stockées
Services basés sur les procédures stockées (exemple)