Operadores de horas

4D v16.3

Operadores de horas

Una expresión que utiliza un operador de horas devuelve una hora o un número, dependiendo de la operación. La siguiente tabla muestra los operadores de horas:

Operación	Sintaxis	Devuelve	Expresión	Valor
Adición	Hora+ Hora	Hora	?02:03:04? + ?01:02:03?	?03:05:07?
Substracción	Hora– Hora	Hora	?02:03:04? – ?01:02:03?	?01:01:01?
Adición	Hora + Número	Número	?02:03:04? + 65	7449
Substracción	Hora – Número	Número	?02:03:04? – 65	7319
Multiplicación	Hora * Número	Número	?02:03:04? * 2	14768
División	Hora / Número	Número	?02:03:04? / 2	3692
División entera	Hora \ Número	Número	?02:03:04? \ 2	3692
Módulo	Hora % Hora	Hora	?20:10:00? % ?04:20:00?	?02:50:00?
Módulo	Hora % Número	Número	?02:03:04? % 2	0

Ejemplo 1

Puede combinar expresiones de tipo hora y de tipo numérico utilizando los comandos Time y Time string. Por ejemplo:

  //La siguiente línea asigna a la variable $vlSegundos el número de segundos que transcurrirán entre la media noche y una hora a partir de ahora

 $vlSeconds:=Current time+3600

  //La línea siguiente asigna a $vHSoon la hora que será en una hora

 $vhSoon:=Time(Current time+3600)

La segunda línea puede escribirse de una manera más simple:

  //La línea siguiente asigna a $vhSoon la hora que será en una hora

 $vhSoon:=Current time+?01:00:00?

Algunas situaciones podrían requerir que usted convierta una expresión de tiempo en una expresión numérica.
Por ejemplo, usted abre un documento utilizando Open document, el cual devuelve un número de referencia de documento (DocRef) que es una expresión de tipo hora. Más adelante, usted quiere pasar DocRef a una rutina de plug-in 4D que espera un valor numérico como número de referencia de documento. En tal caso, utilice la adición con 0 (cero) para obtener un valor numérico de un valor de tiempo, pero sin cambiar su valor. Por ejemplo:

  ` Seleccionar y abrir un documento

 $vhDocRef:=Open document("")

 If(OK=1)

  ` Pase la expresión hora DocRef como una expresión numérica para una rutina de extensión 4D

    DO SOMETHING SPECIAL(0+$vhDocRef)

 End if

Ejemplo 3

El operador Modulo permite añadir horas teniendo en cuenta el formato 24 horas de un día:

 $t1:=?23:00:00? // Son las 23:00 p.m.

  // Queremos añadir 2 horas y media

 $t2:=$t1 +?02:30:00? // Con una adición simple, $t2 es ?25:30:00?

 $t2:=($t1 +?02:30:00?)%?24:00:00? // $t2 es ?01:30:00? y son la 1:30 a.m. del siguiente día

Ver también

Operadores
Operadores de bits
Operadores de cadenas
Operadores de comparación
Operadores de fechas
Operadores de imágenes
Operadores lógicos
Operadores numéricos

4D v16.3

Operadores de horas