4D v16.3
ON ERR CALL
ON ERR CALL
| ON ERR CALL ( metodoErro ) | ||||||||
| Parâmetro | Tipo | Descrição | ||||||
| metodoErro | String |
|
Método de erro a ser chamado, ou string Vazia para não capturar erros | |||||
O comando ON ERR CALL instala o método de projeto, cujo nome se passa em metodoErro, como método de tratamento de ocorrências ou método de gestão de erros.
Uma vez que se instala um projeto de controle de erros, 4D chama ao método cada vez que se produz um erro durante a execução de um comando de linguagem 4D.
O alcance deste comando é o processo atual. Só pode ter um método de gestão de erros por processo, mas pode ter diferentes métodos de gestão de erros para vários processos. Para parar um método de gestão de erros, chame de novo ON ERR CALL e passe uma string vazia em metodoError.Notas:
- no contexto de uso dos componentes, este comando se aplica apenas ao banco de dados atual. Se um erro for gerado a partir de um componente, métodoErro não é chamado no banco de dados host
- Se ON ERR CALL for chamado desde um processo para o qual você já tenha solicitado execución preemptiva (em modo compilado 64 bits), o compilador verifica se metodoErro é thread seguro e devolve os erros se não for compatível com o modo apropiativo. Para saber mais, consulte [#title id="8733"/].
Para parar a identificação de erros, chame ON ERR CALL novamente e passe a string vazia em errorMethod.
Pode identificar erros lendo a variável sistema Error, a qual contém o número de código do erro. Os códigos de erros são listados no tema Códigos de Erro. Para maior informação, consulte a seção Erros de Sintaxe (1 -> 81). O valor da variável Error é significativo só no método de gestão de erros; se necessitar o código do erro no método que provocou o erro, copie a variável Error em sua própria variável processo. Também pode acessar as variáveis sistema Error method e Error line as quais contém respectivamente, o nome do método e o número de linha onde ocorreu o erro (ver Error, Error method, Error line).
Pode usar o comando GET LAST ERROR STACK para obter a sequência de errors (ou seja a pilha de erros) na fonte da interrupçãoo.
O método de gestão de erros deve tratar os erros de maneira apropriada ou mostrar uma mensagem de erro ao usuário. Os erros podem ser gerados por:
- O motor de banco de dados de 4D; por exemplo, quando guarda um registro trata de duplicar uma chave de índice único.
- O ambiente de 4D; por exemplo, quando não tem suficiente memoria para encher um array.
- O sistema operativo no qual é executado o banco; por exemplo, disco cheio ou erros de entrada/saída.
O comando ABORT pode ser utilizado para terminar o processo. Se não chamar ABORT no método instalado, 4D devolve o método interrompido e continua a execução do método. Utilize o comando ABORT quando a execução não pode ser recuperado.
Se ocorrer um erro no método de gestão de erros, 4D retoma o controle da gestão de erros. Portanto, deve ter certeza de que o método de gestão de erros não possa gerar um erro. Igualmente, não pode utilizar ON ERR CALL dentro do método de gestão de erros.
ON ERR CALL geralmente é localizado no método banco de abertura de uma aplicação, para manipular os erros para esta aplicação. ON ERR CALL pode igualmente ser localizado ao início de um método para manipular os erros específicos deste método.
O método de projeto a seguir trata de criar um documento cujo nome é recebido como parâmetro. Se não for possível criar o documento, o método de projeto retorna 0 (zero) ou o código de erro:
` Método de projeto Criar doc
` Criar doc ( String ; Pointer ) -> Inteiro longo
` Criar doc ( DocName ; ->DocRef ) -> Código de erro resultante
gError:=0
ON ERR CALL("IO GESTOR DE ERROS")
$2->:=Create document($1)
ON ERR CALL("")
$0:=gErrorO método de projeto IO_GESTOR_ERROS é o seguinte:
` Método de projeto IO_GESTOR_ERROS gError:=Error ` Simplesmente copie o código do erro na variável de processo gErrorNote a utilização da variável processo gError para obter o código do erro no método de execução atual. Quando estes métodos estiverem presentes em seu banco de dados, pode escrever:
` ...
C_TIME(vhDocRef)
$vlErrCode:=Criar doc($vsDocumentNome;->vhDocRef)
If($vlErrCode=0)
`...
CLOSE DOCUMENT($vlErrCode)
Else
ALERT("O documento não pode ser criado, erro de E/S "+String($vlErrCode))
End ifVer o exemplo da seção Arrays e Memória.
Enquanto implementa um conjunto de operações complexas, pode terminar com várias subrotinas que necessitem diferentes métodos de gestão de erros. Só pode ter um método de gestão de erros por processo, de maneira que tem duas opções:
- Manter contato com o método atual cada vez que chama a ON ERR CALL, ou
- Utiliza a variável array processo (neste caso, asMetodoErro) para “empilhar” os métodos de gestão de erros e um método de projeto (neste caso, ON ERROR CALL) para instalar e reinstalar os métodos de gestão de erros.
Deve inicializar o array ao começo da execução do processo:
` NAO esqueça inicializar o array ao início
` do método de processo (o método de projeto que executa o processo)
ARRAY STRING(63;asMetodoErro;0)Este é o método personalizado ON ERROR CALL:
` Método de projeto ON ERROR CALL
` ON ERROR CALL { ( String) }
` ON ERROR CALL { ( Nome do método ) }
C_STRING(63;$1;$MetodoErro)
C_LONGINT($vlElem)
If(Count parameters>0)
$MetodoErro:=$1
Else
$MetodoErro:=""
End if
If($MetodoErro#"")
C_LONGINT(gError)
gError:=0
$vlElem:=1+Size of array(asMetodoErro)
INSERT IN ARRAY(asMetodoErro;$vlElem)
asMetodoErro{$vlElem}:=$1
ON ERR CALL($1)
Else
ON ERR CALL("")
$vlElem:=Size of array(asMetodoErro)
If($vlElem>0)
DELETE FROM ARRAY(asMetodoErro;$vlElem)
If($vlElem>1)
ON ERR CALL(asMetodoErro{$vlElem-1})
End if
End if
End ifDepois, pode chamá-lo desta maneira:
gError:=0
ON ERROR CALL("IO ERRORS") ` Instale o método de gestão de erros IO ERRORS
` ...
ON ERROR CALL("ALL ERRORS") ` Instale o método de gestão de erros ALL ERRORS ` ...
ON ERROR CALL ` Reinstale o método de gestão de erros ALL ERRORS e reinstale IO ERRORS
` ...
ON ERROR CALL ` Reinstale o método de gestão de erros IO ERRORS
` ...O método abaixo de gestão de erros ignora as interrupções de usuário e mostra o texto do erro:
//Método de projeco Show_errors_only
If(Error#1006) //esta não é uma interrupção do usuário
ALERT("The error "+String(Error)+" occurred. The code in question is: \""+Error formula+"\"")
End if
ABORT
GET LAST ERROR STACK
Method called on error
Variáveis sistema
Produto: 4D
Tema: Interrupções
Número
155
Criado por: < 4D v6
Modificado: 4D v12
Modificado: 4D v15 R5
Manual de linguagem 4D ( 4D v16)
Manual de linguagem 4D ( 4D v16.1)
Manual de linguagem 4D ( 4D v16.2)
Manual de linguagem 4D ( 4D v16.3)
