Drop position

4D v16.3

Drop position


Drop position {( numColonne \| posYImage )} -> Résultat

Paramètre	Type	Description
numColonne \| posYImage	Entier long	Numéro de colonne de list box (-1 si le déposer a lieu après la dernière colonne) ou Position coordonnée Y dans l'image
Résultat	Entier long	• Numéro (tableau/list box) ou • Position (liste hiérarchique) ou • Position dans la chaîne (texte/combo box) de l'élément de destination ou • -1 si le déposer a lieu après le dernier élément de tableau ou de liste ou • Position coordonnée X dans l’image

Description

Drop position permet de connaître l'emplacement, dans un objet de destination “complexe”, auquel un objet a été (glissé et) déposé. Généralement, vous utiliserez Drop position pendant le traitement d'un événement glisser-déposer qui s'est produit dans un tableau, une list box, une liste hiérarchique, un champ texte ou une image.

Si l'objet de destination est un tableau, la fonction retourne un numéro d'élément.
Si l'objet de destination est une list box, la fonction retourne un numéro de ligne. Dans ce cas, la fonction retourne également dans le paramètre facultatif numColonne le numéro de la colonne sur laquelle le déposer a eu lieu.
Si l'objet de destination est une liste hiérarchique, la fonction retourne une position d'élément.
Si l'objet de destination est une variable ou un champ de type texte ou encore une combo box, la fonction retourne une position de caractère à l'intérieur de la chaîne.
Dans tous les cas ci-dessus, la fonction retourne -1 si l'objet source a été déposé après le dernier élément de l'objet de destination.
Si l'objet de destination est une variable ou un champ de type image, la fonction retourne l’emplacement horizontal du clic et, dans le paramètre facultatif posYImage, l’emplacement vertical du clic. Les valeurs retournées sont exprimées en pixels et relativement au système de coordonnées locales.

Si vous appelez Drop position pendant le traitement d'un événement qui n'est pas de type glisser-déposer dans un tableau, une list box, une combo box, une liste hiérarchique, un texte ou une image, la fonction retourne également -1.

Rappel : Pour qu'un objet de formulaire accepte des données déposées, la propriété Déposable doit lui avoir été assignée. De plus, sa méthode objet doit être appelée par l'événement On Drag Over et/ou On Drop si vous voulez pouvoir gérer ce type d'événement.

Exemple 1

Reportez-vous aux exemples de la commande DRAG AND DROP PROPERTIES.

Exemple 2

Dans l’exemple suivant, une liste de sommes doit être ventilée par mois et par personne. L’opération s’effectue par glisser-déposer depuis une zone de défilement :

La méthode objet de la list box contient le code suivant :

 Case of

    :(Form event=On Drag Over)

       DRAG AND DROP PROPERTIES($source;$lignetab;$numprocess)

       If($source=Get pointer("ZD1")) `Si le déposer provient bien de la zone de défilement

          $0:=0

       Else

          $0:=-1 `On refuse le déposer

       End if

    :(Form event=On Drop)

       DRAG AND DROP PROPERTIES($source;$lignetab;$numprocess)

       $numligne:=Drop position($numcol)

       If($numcol=1)

          BEEP

       Else

          Case of `Addition des valeurs déposées

             :($numcol=2)

                Jean{$numligne}:=Jean{$numligne}+ZD1{$lignetab}

             :($numcol=3)

                Marc{$numligne}:=Marc{$numligne}+ZD1{$lignetab}

             :($numcol=4)

                Pierre{$numligne}:=Pierre{$numligne}+ZD1{$lignetab}

          End case

          DELETE FROM ARRAY(ZD1;$lignetab) `Mise à jour de la zone

       End if

 End case

Voir aussi

DRAG AND DROP PROPERTIES
Présentation du Glisser-Déposer