4D v16.3
Current date
Current date
| Current date {( * )} -> Funktionsergebnis | ||||||||
| Parameter | Typ | Beschreibung | ||||||
| * | Operator |
|
Gibt das aktuelle Datum vom Server zurück | |||||
| Funktionsergebnis | Datum |
|
Aktuelles Datum | |||||
Die Funktion Current date gibt das aktuelle Tagesdatum zurück. Es entspricht dem Datum vom System des Rechners.
4D Server: Verwenden Sie den optionalen Parameter (*) auf dem remote Rechner, gibt er das aktuelle Datum des Servers zurück.
Folgendes Beispiel zeigt eine Meldung mit dem aktuellen Datum an:
ALERT("Das Datum ist "+String(Current date)+".")Erstellen Sie eine Anwendung für den internationalen Markt, müssen Sie u.U. wissen, ob Ihre 4D Version mit Datumsangaben im Format MM/DD/YYYY (US Version) oder DD.MM.YYYY (deutsche Version) läuft. Das ist hilfreich beim Einrichten von Feldern zur Eingabe von Datum.
Verwenden Sie dafür die folgende Projektmethode:
` Sys date format globale Funktion
` Sys date format -> String
` Sys date format -> Standardmäßiges 4D Datumsformat
C_STRING(31;$0;$vsDate;$vsMDY;$vsMonth;$vsDay;$vsYear)
C_LONGINT($1;$vlPos)
C_DATE($vdDate)
`Erhalte Datumswert, wo Werte für Monat, Tag und Jahr alle unterschiedlich sind.
$vdDate:=Current date
Repeat
$vsMonth:=String(Month of($vdDate))
$vsDay:=String(Day of($vdDate))
$vsYear:=String(Year of($vdDate)%100)
If(($vsMonth=$vsDay)|($vsMonth=$vsYear)|($vsDay=$vsYear))
vOK:=0
$vdDate:=$vdDate+1
Else
vOK:=1
End if
Until(vOK=1)
$0:="" `Initialisiere Funktionsergebnis
$vsDate:=String($vdDate)
$vlPos:=Position("/";$vsDate) `Suche ersten / Trenner im String ../../..
$vsMDY:=Substring($vsDate;1;$vlPos-1) `Extrahiere die erste Stelle vom Datum
$vsDate:=Substring($vsDate;$vlPos+1) `Entferne die ersten Stellen und ersten / Trenner
Case of
:($vsMDY=$vsMonth) `Stellen zeigen den Monat an
$0:="MM"
:($vsMDY=$vsDay) `Stellen zeigen den Tag an
$0:="DD"
:($vsMDY=$vsYear) `Stellen zeigen das Jahr an
$0:="YYYY"
End case
$0:=$0+"/" `Starte mit Aufbau des Funktionsergebnisses
$vlPos:=Position("/";$vsDate) `Suche zweiten / Trenner im String ../..
$vsMDY:=Substring($vsDate;1;$vlPos-1) `Extrahiere die nächsten Stellen aus dem Datum
$vsDate:=Substring($vsDate;$vlPos+1) `Reduziere den String auf die letzten Stellen im Datum
Case of
:($vsMDY=$vsMonth) `Stellen zeigen den Monat an
$0:=$0+"MM"
:($vsMDY=$vsDay) `Stellen zeigen den Tag an
$0:=$0+"DD"
:($vsMDY=$vsYear) `Stellen zeigen das Jahr an
$0:=$0+"YYYY"
End case
$0:=$0+"/" `Fahre fort mit Aufbau des Funktionsergebnisses
Case of
:($vsDate=$vsMonth) `Stellen zeigen den Monat an
$0:=$0+"MM"
:($vsDate=$vsDay) `Stellen zeigen den Tag an
$0:=$0+"DD"
:($vsDate=$vsYear) `Stellen zeigen das Jahr an
$0:=$0+"YYYY"
End case
`An diesem Punkt ist $0 gleich MM/DD/YYYY oder DD.MM.YYYY oder...
Produkt: 4D
Thema: Datum und Zeit
Nummer:
33
Erstellt: < 4D v6
4D Programmiersprache ( 4D v16)
4D Programmiersprache ( 4D v16.1)
4D Programmiersprache ( 4D v16.2)
4D Programmiersprache ( 4D v16.3)
