WR INSERER LIEN HYPERTEXTE

4D Write v16


WR INSERER LIEN HYPERTEXTE ( zone ; typeLien ; styleURL ; libelléLien ; contenuLien ; refMéthode )

Paramètre	Type	Description
zone	Entier long	Zone 4D Write
typeLien	Entier	Type de lien hypertexte : 0 = Méthode, 1 = URL, 2 = Document 4D Write
styleURL	Entier	Apparence de l’URL : 1 = style par défaut, 0 = style personnalisé
libelléLien	Texte	Libellé du lien (apparaissant dans le document)
contenuLien	Texte	Contenu du lien
refMéthode	Entier long	Valeur pour $3, 3e paramètre de la méthode (si le lien est une méthode)

Description

La commande WR INSERER LIEN HYPERTEXTE insère dans zone une référence de type “lien hypertexte”, à l’emplacement courant du curseur ou à la place de la sélection courante.

typeLien
Le paramètre typeLien permet de définir le type du lien hypertexte à insérer. 4D Write admet trois types de liens hypertextes : les liens de type méthode, les liens de type URL et les liens de type document.

Un lien de type méthode permet de lancer l’exécution d’une méthode 4D lors du clic sur la référence. La méthode ne peut pas être une fonction, et il n’est pas possible de lui passer des paramètres. Elle peut toutefois recevoir deux ou trois valeurs dans $1, $2 et, optionnellement, $3 :
- $1 (Entier long) contient la référence de la zone 4D Write,
- $2 (Texte) contient le libellé du lien,
- $3 (Entier long) contient une valeur numérique arbitraire que vous aurez éventuellement associé au lien, à l’aide du paramètre refMethode ou via l'interface utilisateur de la base.
  Note : En vue de la compilation de la base, il est nécessaire de déclarer $1 et $3 en Entier long et $2 en Texte, même si vous ne les utilisez pas.

Un lien de type URL permet d’ouvrir le navigateur par défaut de la machine et d’accéder à un URL spécifique, défini dans le paramètre contenuLien.
Un lien de type document provoque, lors du clic sur le lien, le remplacement du document courant par un autre document dont le chemin d’accès a été passé dans le paramètre contenuLien. Bien entendu, le format du document à ouvrir doit être reconnu par 4D Write.

Passez dans le paramètre typeLien l'une des constantes suivantes, placées dans le thème "WR Paramètres" :

Constante	Type	Valeur	Comment
wr lien de type méthode	Entier long	0	Insère un lien de type méthode.
wr lien de type URL	Entier long	1	Insère un lien de type URL.
wr lien de type document	Entier long	2	Insère un lien de type document.

styleURL
Le paramètre styleURL permet de définir l’apparence du lien hypertexte inséré. Vous pouvez passer dans ce paramètre l'une des constantes suivantes, placées dans le thème "WR Paramètres" :

Constante	Type	Valeur	Comment
wr lien apparence personnalisée	Entier long	0	Permet d'utiliser une apparence personnalisée. Dans ce cas, vous devrez sélectionner le lien et lui affecter un style à l’aide de la commande WR FIXER PROPRIETE TEXTE.
wr lien apparence par defaut	Entier long	1	Conserve l’apparence par défaut des liens hypertexte (texte bleu souligné). Les couleurs par défaut peuvent être modifiées par programmation, à l’aide de la commande WR FIXER PROPRIETE DOCUMENT.

Si vous utilisez la constante wr lien apparence personnalisée et n’affectez pas de style au lien, il prendra l’apparence du texte courant (il ne sera pas graphiquement matérialisé).

libelléLien
Le paramètre libelléLien permet de définir le libellé visible du lien (en affichage des valeurs).

contenuLien
Le paramètre contenuLien contient la valeur hypertexte du lien. La nature de cette valeur dépend du type de lien :

pour un lien de type Méthode 4D, passez le nom de la méthode (par exemple “TriClients”),
pour un lien de type URL, passez l’URL complet (par exemple “http://www.4D.fr/”),
pour un lien de type Document, passez le chemin d’accès absolu du document (par exemple “C:\MonDossier\MonDoc.4w7” sous Windows, ou “DisqueDur:MonDossier:MonDoc” sous Mac OS).

refMéthode
Le paramètre refMéthode permet, lorsque le lien est de type méthode 4D, de passer une valeur supplémentaire à la méthode appelée. La méthode recevra cette valeur dans le paramètre $3 (de type Entier long).

Note : L’insertion et la gestion de liens hypertexte est également accessible dans le mode Utilisation de 4D Write.

Exemple 1

Vous souhaitez insérer l’URL de votre site Web dans une zone 4D Write:

 WR INSERER LIEN HYPERTEXTE(zone;wr lien de type URL;wr lien apparence par defaut;"Visitez ce superbe site";"http:/www.MonSite.com/")

Exemple 2

Dans vos documents 4D Write, vous proposez une interface de navigation hypertexte basée sur des liens de type document. La méthode suivante gère dynamiquement les chemins d'accès, quelle que soit la plate-forme :

 $Doc:=Fichier structure

 Doc:=$Doc

 Tant que(Position(":";$Doc)#0)

    $Doc:=Sous chaine($Doc;1+Position(":";$Doc);Longueur($Doc))

    $Long:=Longueur($Doc)

 Fin tant que

 Doc:=Sous chaine(Doc;1;Longueur(Doc)-$Long)

 PROPRIETES PLATE FORME($Platf;$Syst;$Machine)

 Si($Platf=Windows)

    $nom:=Doc+"Documentation"+"/"+"01_Introduction.4W7"

 Sinon

    $nom:=Doc+"Documentation"+":"+"01_Introduction.4W7"

 Fin de si

 $titre:="Voirla documentation"

 WR INSERER LIEN HYPERTEXTE(ZoneWrite;wr lien de type document;wr lien apparence par defaut;$titre;$nom)

Exemple 3

Cet exemple illustre l'emploi des liens de type méthode. Dans votre document, vous souhaitez que l'utilisateur puisse saisir des informations, par exemple son nom et son prénom, à des emplacements spécifiques. Pour cela, vous insérez un lien qui appelle la méthode M_LiensHypertexte. Cette méthode demande à l'utilisateur de saisir soit son nom soit son prénom, suivant la valeur passée dans $3. La valeur saisie remplace alors le lien :

  `Méthode M_LiensHypertexte

 C_ENTIER LONG($1;$3)

 C_TEXTE($2)

 Au cas ou

    :($3=1)

       WR INSERER TEXTE($1;Demander("Saisissez votre prénom"))

    :($3=2)

       WR INSERER TEXTE($1;Demander("Saisissez votre nom"))

 Fin de cas

 WR LIRE SELECTION($1;$deb;$fin)

 WR FIXER SELECTION($1;$deb;$fin+1)

 WR EXECUTER COMMANDE($1;wr cmd effacer)

Pour insérer le lien de type méthode dans la zone 4D Write :

 $titre:="Cliquez pour saisir"

 $méthode:="M_LiensHypertexte"

 WR INSERER TEXTE(Zone;"Nom : ")

 WR INSERER LIEN HYPERTEXTE(Zone;wr lien de type méthode;wr lien apparence par defaut;$titre;$méthode;1)

 WR INSERER TEXTE(Zone;Caractere(Retour chariot)+"Prénom : ")

 WR INSERER LIEN HYPERTEXTE(Zone;wr lien de type méthode;wr lien apparence par defaut;"Cliquez pour saisir";"M_LiensHypertexte";2)

Voir aussi

WR LIRE LIEN HYPERTEXTE