PV Couleur vers index

4D View v16


PV Couleur vers index ( couleur ) -> Résultat

Paramètre	Type	Description
couleur	Entier long	Numéro de couleur
Résultat	Entier	Numéro de couleur indexée

Description

La commande PV Couleur vers index retourne le numéro dans la palette 4D de la couleur indexée correspondant à la couleur RVB définie par l'entier long couleur.

L’entier retourné par la commande indique la couleur indexée la plus proche possible de la couleur passée en paramètre. Ce résultat, compris entre 0 et 255, utilise comme référence les 256 couleurs de la palette de 4D.

Reportez-vous à la description des commandes 4D suivantes pour des informations détaillées sur les couleurs dans 4D :

OBJET FIXER COULEURS RVB pour le système de couleurs RVB utilisé par 4D.
OBJET FIXER COULEUR pour la palette 4D de couleurs indexées.

Note : Le codage interne des couleurs de 4D View est de type BVR, il est inversé par rapport au codage RVB de 4D ; les principes d'utilisation sont toutefois identiques.

Exemple

Cette méthode attribue à la cellule A1 la couleur de fond définie par les valeurs RVB (0 à 255) saisies dans les cellules A2, A3 et A4. La cellule C1 affiche, pour sa part, le numéro de couleur indexée le plus proche dans la palette 4D — avec la couleur de fond ad hoc — tandis que les cellules C2, C3 et C4 affichent les valeurs RVB correspondant à cette couleur indexée, permettant ainsi de visualiser l'écart avec les valeurs de départ.

 C_ENTIER LONG($Couleur) //Couleur de fond de la cellule A1 (RVB) puis couleur après indexation

 C_ENTIER LONG($Rouge;$Vert;$Bleu) //Couleurs RVB de départ puis d'arrivée

 C_ENTIER LONG($Index) //Numéro dans la palette 4D

 

 PV FIXER VALEUR CELL ALPHA(Zone;2;1;"Couleur") //Libellés

 PV FIXER VALEUR CELL ALPHA(Zone;2;2;"Rouge")

 PV FIXER VALEUR CELL ALPHA(Zone;2;3;"Vert")

 PV FIXER VALEUR CELL ALPHA(Zone;2;4;"Bleu")

 

 $Rouge:=PV Lire valeur cell nombre(Zone;1;2) //Couleurs RVB de départ

 $Vert:=PV Lire valeur cell nombre(Zone;1;3)

 $Bleu:=PV Lire valeur cell nombre(Zone;1;4)

 

 $Couleur:=PV RVB vers couleur($Rouge;$Vert;$Bleu)

 PV FIXER PROPRIETE CELLULE(Zone;1;1;pv style couleur fond impair;$Couleur) //Affectation du fond A1

 

 $Index:=PV Couleur vers index($Couleur) //"Indexation"

 PV FIXER VALEUR CELL NOMBRE(Zone;3;1;$Index) //Numéro dans la palette 4D

 $Couleur:=PV Index vers couleur($Index) //Nouvelle couleur

 PV FIXER PROPRIETE CELLULE(Zone;3;1;pv style couleur fond impair;$Couleur) //Affectation du fond C1

 

 PV COULEUR VERS RVB($Couleur;$Rouge;$Vert;$Bleu) //Décomposons

 PV FIXER VALEUR CELL NOMBRE(Zone;3;2;$Rouge) //Couleurs RVB d'arrivée après "indexation"

 PV FIXER VALEUR CELL NOMBRE(Zone;3;3;$Vert)

 PV FIXER VALEUR CELL NOMBRE(Zone;3;4;$Bleu)

Voir aussi

PV Index vers couleur