4D Doc Center : XML DECODER

4D v14.3

XML

XML DECODER


XML DECODER ( valeurXML ; objet4D )

Paramètre	Type	Description
valeurXML	Texte	Valeur de type texte provenant d’une structure XML
objet4D	Champ, Variable	Variable ou champ 4D devant recevoir la valeur XML convertie

Description

La commande XML DECODER convertit une valeur stockée en tant que chaîne XML en une valeur 4D typée. La conversion est effectuée automatiquement en fonction de règles suivantes :

Valeur	Exemples	Conversion sur système français
numérique	<Prix>8,5</Prix><Prix>8.5</Prix>	Réel : 8,5
booléenne	<Double>1</Double> <Double>0</Double> ou <Double>vrai</Double> <Double>faux</Double>	Booléen : Vrai/Faux
BLOB		Décodage base64
Images		Décodage base64 + commande BLOB vers image
Dates	2009-10-25T01:03:20+01:00	Suppression de la partie heure et du fuseau horaire : !25/10/2009!
Heures	2009-10-25T01:03:20+01:00	Suppression de la partie date et du fuseau horaire : ?01:03:20?

Exemple

Importation de données depuis un document XML dans lequel les valeurs sont stockées en tant qu’attributs.
Exemple de document XML :


<CD Date="2003-01-01T00:00:00Z" Description="Ce double CD réédité par EMI en 1995 réunit 4 Stabat mater. Celui de Rossini interprété par l'orchestre Symphonique de Berlin dirigé par Karl Forster. Il est suivi de l'œuvre de Verdi, Philharmonia Orchestra dirigé par Carlo Maria Giulini. Sur le deuxième CD, on trouve Francis Poulenc interprété par Régine Crespin. Cette compilation se termine avec une version moins connue, celle du polonais Karol Szymanowski. Orchestre Symphonique de la Radio Nationale polonaise dirigée par Antoni Wit" Double="true" Duree="7246" Genre="Musique sacrée" ID_CD="5" Interprete="Divers" Prix="8.5" Titre="4 Stabat mater"/>

 Repeter

       MyEvent:=SAX Lire noeud XML(DocRef)

 

       Au cas ou

       :(MyEvent=XML début élément)

          TABLEAU TEXTE(tAttrNames;0)

          TABLEAU TEXTE(tAttrValues;0)

          SAX LIRE ELEMENT XML(DocRef;vName;vPrefix;tAttrNames;tAttrValues)

          Si(vName="CD")

             CREER ENREGISTREMENT([CD])

             Boucle($i;1;Taille tableau(tAttrNames))

                $attrName:=tAttrNames{$i}

                Au cas ou

                :($attrName="ID_CD")

                   XML DECODER(tAttrValues{$i};[CD]ID_CD)

                :($attrName="Titre")

                   [CD]uvre:=tAttrValues{$i}

                :($attrName="Prix")

                   XML DECODER(tAttrValues{$i};[CD]Prix)

                :($attrName="Date")

                   XML DECODER(tAttrValues{$i};[CD]Date saisie)

                :($attrName="Duree")

                   XML DECODER(tAttrValues{$i};[CD]Durée_totale)

                :($attrName="Double")

                   XML DECODER(tAttrValues{$i};[CD]CD_Double)

                Fin de cas

             Fin de boucle

          Fin de si

       ...

       Fin de cas

 Jusque(MyEvent=XML fin document)