4D v14.3
WA FIXER FILTRES URL
- 4D - Langage
-
- Zone Web
-
- Gestion programmée des zones Web
- WA ACTUALISER URL
- WA AGRANDIR TEXTE PAGE
- WA ARRETER CHARGEMENT URL
- WA Creer menu historique URL
- WA Evaluer JavaScriptMod
- WA EXECUTER FONCTION JAVASCRIPTMod
- WA FIXER CONTENU PAGE
- WA FIXER FILTRES LIENS EXTERNES
- WA FIXER FILTRES URL
- WA FIXER PREFERENCEMod
- WA Lire contenu page
- WA Lire dernier URL filtre
- WA LIRE DERNIERE ERREUR URL
- WA LIRE FILTRES LIENS EXTERNES
- WA LIRE FILTRES URL
- WA LIRE HISTORIQUE URL
- WA LIRE PREFERENCE
- WA Lire titre page
- WA Lire URL courant
- WA OUVRIR URL
- WA OUVRIR URL PRECEDENT
- WA OUVRIR URL SUIVANT
- WA REDUIRE TEXTE PAGE
- WA URL precedent disponible
- WA URL suivant disponible
WA FIXER FILTRES URL
| WA FIXER FILTRES URL ( {* ;} objet ; tabFiltres ; tabAutorisRefus ) | ||||||||
| Paramètre | Type | Description | ||||||
| * | Opérateur |
|
Si spécifié, objet est un nom d'objet (chaîne) Si omis, objet est une variable | |||||
| objet | Objet de formulaire |
|
Nom d'objet (si * est spécifié) ou Variable (si * est omis) | |||||
| tabFiltres | Tableau chaîne |
|
Tableau de filtres | |||||
| tabAutorisRefus | Tableau booléen |
|
Tableau autoriser-refuser | |||||
La commande WA FIXER FILTRES URL permet de mettre en place un ou plusieurs filtre(s) pour la zone Web désignée par les paramètres * et objet.
Avant le chargement de toute page demandée par l’utilisateur, 4D consulte la liste des filtres afin de vérifier si l’URL cible est autorisé ou non. L’évaluation de l’URL est basée sur le contenu des tableaux tabFiltres et tabAutorisRefus s'ils ont été définis.
Si l’URL demandé n’est pas autorisé, il n’est pas chargé et l’événement formulaire Sur filtrage URL est généré (cf. commande Evenement formulaire).
Les tableaux tabFiltres et tabAutorisRefus doivent être synchronisés.
- Chaque ligne du tableau tabFiltres doit contenir un URL devant être filtré. Vous pouvez utiliser le * comme joker de remplacement pour un ou plusieurs caractère(s).
- Chaque ligne correspondante dans le tableau tabAutorisRefus doit contenur un booléen indiquant si l’URL doit être autorisé (Vrai) ou refusé (Faux).
En cas de contradiction au niveau des paramétrages (autorisation et refus d’un même URL), le paramétrage pris en compte est le dernier.
Pour désactiver le filtrage des URLs, appelez la commande en lui passant des tableaux vides ou en passant respectivement les valeurs "*" et Vrai dans la dernière ligne des tableaux tabFiltres et tabAutorisRefus.
Une fois la commande exécutée, les filtres deviennent une propriété de la zone Web. Si les tableaux tabFiltres et tabAutorisRefus sont supprimés ou réinitialisés, les filtres restent actifs tant que la commande n’a pas été exécutée à nouveau. Pour connaître les filtres actifs pour une zone, vous devez utiliser la commande WA LIRE FILTRES URL.
Important : Le filtrage des URLs effectué par cette commande s’applique uniquement à la variable "URL" associée à la zone Web (variable généralement saisissable et affichée dans le formulaire).
Le filtrage ne s’applique pas à la commande WA OUVRIR URL ni aux autres commandes de navigation.
Vous souhaitez interdire l’accès à tous les sites web .org, .net et .fr :
TABLEAU TEXTE($filters;0)
TABLEAU BOOLEEN($AllowDeny;0)
AJOUTER A TABLEAU($filters;"*.org")
AJOUTER A TABLEAU($AllowDeny;Faux)
AJOUTER A TABLEAU($filters;"*.net")
AJOUTER A TABLEAU($AllowDeny;Faux)
AJOUTER A TABLEAU($filters;"*.fr")
AJOUTER A TABLEAU($AllowDeny;Faux)
WA FIXER FILTRES URL(MyWArea;$filters;$AllowDeny)Vous souhaitez interdire l’accès à tous les sites web sauf les sites russes (.ru) :
TABLEAU TEXTE($filters;0)
TABLEAU BOOLEEN($AllowDeny;0)
AJOUTER A TABLEAU($filters;"*") `Tout sélectionner
AJOUTER A TABLEAU($AllowDeny;Faux) `Tout interdire
AJOUTER A TABLEAU($filters;"www.*.ru") `Sélectionner *.ru
AJOUTER A TABLEAU($AllowDeny;Vrai) `Autoriser
WA FIXER FILTRES URL(MyWArea;$filters;$AllowDeny)Vous souhaitez donner accès aux sites Web 4D uniquement (.com, .fr, .es, etc.) :
TABLEAU TEXTE($filters;0)
TABLEAU BOOLEEN($AllowDeny;0)
AJOUTER A TABLEAU($filters;"*") `Tout sélectionner
AJOUTER A TABLEAU($AllowDeny;Faux) `Tout interdire
AJOUTER A TABLEAU($filters;"www.4D.*") `Sélectionner 4d.fr, 4d.com...
AJOUTER A TABLEAU($AllowDeny;Vrai) `Autoriser
WA FIXER FILTRES URL(MyWArea;$filters;$AllowDeny)Vous souhaitez autoriser l’accès local à la documentation uniquement (située dans le dossier C://doc) :
TABLEAU TEXTE($filters;0)
TABLEAU BOOLEEN($AllowDeny;0)
AJOUTER A TABLEAU($filters;"*") `Tout sélectionner
AJOUTER A TABLEAU($AllowDeny;Faux) `Tout interdire
AJOUTER A TABLEAU($filters;"file://C:/doc/*") `Sélectionner le chemin file:// autorisé
AJOUTER A TABLEAU($AllowDeny;Vrai)->Autoriser
WA FIXER FILTRES URL(MyWArea;$filters;$AllowDeny)Vous souhaitez autoriser tous les sites sauf un, par exemple celui d’Elcaro :
TABLEAU TEXTE($filters;0)
TABLEAU BOOLEEN($AllowDeny;0)
AJOUTER A TABLEAU($filters;"*")
AJOUTER A TABLEAU($AllowDeny;Vrai) `Tout autoriser
AJOUTER A TABLEAU($filters;"*elcaro*") `Interdire tout ce qui contient elcaro
AJOUTER A TABLEAU($AllowDeny;Faux)
WA FIXER FILTRES URL(MyWArea;$filters;$AllowDeny)Vous souhaitez interdire des adresses IP spécifiques :
TABLEAU TEXTE($filters;0)
TABLEAU BOOLEEN($AllowDeny;0)
AJOUTER A TABLEAU($filters;"*") `Tout sélectionner
AJOUTER A TABLEAU($AllowDeny;Vrai) `Tout autoriser
AJOUTER A TABLEAU($filters;"86.83.*") `Sélectionner les IP débutant par 86.83.
AJOUTER A TABLEAU($AllowDeny;Faux) `Interdire
AJOUTER A TABLEAU($filters;"86.1*") `Sélectionner les IP débutant par 86.1 (86.10, 86.135 etc.)
AJOUTER A TABLEAU($AllowDeny;Faux) `Interdire
`A noter que l’adresse IP d’un domaine peut varier
WA FIXER FILTRES URL(MyWArea;$filters;$AllowDeny)
Produit : 4D
Thème : Zone Web
Numéro :
1030
Nom intl. : WA SET URL FILTERS
Créé : 4D v11 SQL Release 2
WA FIXER FILTRES LIENS EXTERNES
WA LIRE FILTRES URL
4D - Langage ( 4D v11 SQL Release 6)
4D - Langage ( 4D v12.4)
4D - Langage ( 4D v14 R2)
4D - Langage ( 4D v14 R3)
4D - Langage ( 4D v13.5)
4D - Langage ( 4D v14.3)
4D - Langage ( 4D v14 R4)
