4D Doc Center : EFFACER MENU

4D v14.3

EFFACER MENU


EFFACER MENU ( menu )

Paramètre	Type	Description
menu	RefMenu	Référence de menu

Description

La commande EFFACER MENU efface de la mémoire le menu dont vous avez passé l’identifiant dans menu. Ce menu doit avoir été créé par la commande Creer menu. La règle est la suivante : à chaque Creer menu doit correspondre un EFFACER MENU.

La commande efface toutes les instances du menu dans toutes les barres de menus et tous les process. Si le menu appartient à une barre de menus en cours d’utilisation, il continuera à fonctionner mais ne pourra plus être modifié. Il ne sera réellement effacé de la mémoire que lorsque la dernière barre de menus dans laquelle il figure ne sera plus utilisée.

Cette commande peut être appliquée aux menus utilisés comme barres de menus.

Les sous-menus éventuellement utilisés par menu ne sont pas effacés s'ils ont été créés directement via la commande Creer menu. Vous devez dans ce cas les effacer individuellement (cf. règle énoncée ci-dessus). En revanche, s'ils sont issus de la duplication d'un menu existant, n'appelez pas EFFACER MENU avec leurs instances car 4D les efface automatiquement.

Exemple

Cet exemple illustre les cas d'utilisation de cette commande :

 nouvMenu:=Creer menu

 AJOUTER LIGNE MENU(nouvMenu;"Test1")

 sousMenu:=Creer menu

 AJOUTER LIGNE MENU(sousMenu;"SousTest1")

 AJOUTER LIGNE MENU(sousMenu;"SousTest2")  // Création de lignes dans le sous-menu

 

 AJOUTER LIGNE MENU(nouvMenu;"Test2";sousMenu)  // Attacher le sous-menu au menu

 

  //A ce moment, le sous-menu est attaché au menu et si on n'en a plus besoin par la suite, c'est le bon emplacement pour l'effacer.

  //L'effacement ne supprime pas tout de suite sousMenu car il est encore utilisé par nouvMenu. sousMenu sera supprimé quand nouvMenu le sera.

  //Effacer le sous-menu à cet instant permet d'économiser la mémoire

 EFFACER MENU(sousMenu)

 

 $result1:=Pop up menu dynamique(nouvMenu) //Utilisation du menu

 copieMenu:=Creer menu(nouvMenu) // Création d'un menu par copie de nouvMenu (et donc duplication de sousMenu)

 EFFACER MENU(nouvMenu) // On n'a plus besoin de nouvMenu.

 

 $result2:=Pop up menu dynamique(copieMenu)

 EFFACER MENU(copieMenu)

  //Il ne faut pas chercher à effacer le sous-menu de copieMenu puisqu'il n'a pas été créé directement par Creer menu

  //La règle est respectée : à chaque Creer menu correspond un EFFACER MENU