4D Doc Center : WR SET DOCUMENT INFO

4D Write v14

WR SET DOCUMENT INFO


WR SET DOCUMENT INFO ( area ; titulo ; tema ; autor ; empresa ; comentario )

Parámetro	Tipo	Descripción
area	Entero largo	Área 4D Write
titulo	Cadena	Título del documento
tema	Cadena	Tema del documento
autor	Cadena	Autor del documento
empresa	Cadena	Nombre de la empresa
comentario	Texto	Comentarios

Descripción

El comando WR SET DOCUMENT INFO guarda en el documento la información pasada en los parámetros. Desde el punto de vista del usuario, la información se muestra en la caja de diálogo abierta por el menú Herramientas, Información.

El bloqueo del documento se efectúa con ayuda del comando WR LOCK DOCUMENT.

Ejemplo

Usted quiere que los usuarios puedan modificar sólo el Título, Tema y Comentarios. Debe implementar un método de llamada al comando de manera que muestre su propio formulario cuando el usuario elija el comando Información del menú Herramientas.

1. En el método de formulario que contiene el área 4D Write, instale el método de llamada en el código de esta forma:

 Case of

    :(Form event=On Load)

       WR ON COMMAND(WArea;"z65OnCmd")

 End case

2. El método 'z65OnCmd' contiene el siguiente código:

 C_LONGINT($1;$2;$3)

 Case of

    :($2=wr cmd doc information) `=801, si el usuario selecciona Herramientas>Información...

       DIALOG([TheTable];"InfoArea") `Formulario de información personalizada

    Else

       WR EXECUTE COMMAND($1;$2) `Si el usuario selecciona las otras líneas de menús

 End case

3. En el formulario de información personalizado, llamado "InfoArea", sólo las variables vTitle, vSubject y vComments son editables. El método asociado a este formulario es el siguiente:

 Case of

    :(Form event=On Load)

       WR GET DOCUMENT INFO(WArea;vTitle;vSubject;vAuthor;vCy;vComments;DCreat;HCreat;DModif;

       HModif;Lock)

  `Asignación de los elementos vacíos si es necesario

       If(vCy="")

          vCy:="A.C.I."

          vAuthor:=Current user

          vCreation:=String(DCreat)+" at "+Time string(HCreat)

          vModification:=String(DModif)+" at "+Time string(HModif)

       End if

    :(Form event=On Unload) `cuando el formulario se cierra

       WR SET DOCUMENT INFO(WArea;vTitle;vSubject;vAuthor;vCy;vComments)

 End case