4D Doc Center : PV Color to index

4D View v14

PV Color to index


PV Color to index ( color ) -> 戻り値

引数	型	説明
color	倍長整数	カラー番号
戻り値	整数	インデックスカラー番号

説明

PV Color to indexは、デフォルトの4D カラーパレットにおける指定されたRGB color の番号を返します。4D のインデックスカラーの範囲は0 から255 までです。

4D で使用されるRGB カラーに関する詳細は、以下の4Dコマンドの説明を参照してください。

OBJECT SET RGB COLORS： 4D で使用されるRGBカラーシステム用。
OBJECT SET COLOR ： 4D のカラーパレット用。

注: 4D View カラーの内部コーディングはBGR 型で、4DのRGBコーディングに合わせるために反対にされます。しかしながら、使用する際の原理は同じです

例題

このメソッドは、セルA2、A3、A4 に入力されたRGB の値（0 ～ 255）に基づいて設定された背景色をセルA1 に設定します。セルC1 には、暫定的な背景色を使って、4D パレット内で最も近いインデックスカラー番号を表示します。一方、セルC2、C3、C4 にはこのインデックスカラーに対応するRGB の値を表示し、はじめの値との違いを示します。

 C_LONGINT($Color) `A1 セルの背景色（RGB）後にインデックス後のカラー

 C_INTEGER($Red;$Green;$Blue) `はじめのRGBカラーと終了後のRGBカラー

 C_INTEGER($Index) `4D パレット内での番号

 

 PV SET CELL STRING VALUE(Area;2;1;"Color") `ラベル

 PV SET CELL STRING VALUE(Area;2;2;"Red")

 PV SET CELL STRING VALUE(Area;2;3;"Green")

 PV SET CELL STRING VALUE(Area;2;4;"Blue")

 

 $Red:=PV Get cell num value(Area;1;2) `はじめのRGBカラー

 $Green:=PV Get cell num value(Area;1;3)

 $Blue:=PV Get cell num value(Area;1;4)

 

 $Color:=PV RGB to color($Red;$Green;$Blue)

 PV SET CELL PROPERTY(Area;1;1;pv style color back odd;$Color) `A1 の背景色を割り当てる

 

 $Index:=PV Color to index($Color) `"インデックス化"

 PV SET CELL NUM VALUE(Area;3;1;$Index) `4D パレット内での番号

 $Color:=PV Index to color($Index) `新しいカラー

 PV SET CELL PROPERTY(Area;3;1;pv style color back odd;$Color) `C1 セルの背景色を割り当てる

 

 PV COLOR TO RGB($Color;$Red;$Green;$Blue) `分解

 PV SET CELL NUM VALUE(Area;3;2;$Red) `“インデックス化”の後のRGBカラー

 PV SET CELL NUM VALUE(Area;3;3;$Green)

 PV SET CELL NUM VALUE(Area;3;4;$Blue)