4D Doc Center : AP Is Picture Deprecated

4D Pack v14

AP Is Picture Deprecated


AP Is Picture Deprecated ( ptrPict ) -> Résultat

Paramètre	Type	Description
ptrPict	Pointeur	Pointeur vers le champ ou la variable image à tester
Résultat	Entier long	0 = format valide, 1 = format obsolète (PICT)

Description

La commande AP Is Picture Deprecated retourne 1 si l'image référencée par le paramètre ptrPict contient le format PICT (obsolète) et 0 dans le cas contraire. Une image sera considérée comme obsolète si elle est au format PICT ou si elle contient le format PICT (dans le contexte d'images insérées par l'intermédiaire de copier-coller, plusieurs formats peuvent être encapsulés au sein de l'image).

Passez dans ptrPict un pointeur vers le champ image, la variable image ou l'élément de tableau image 4D que vous souhaitez tester.

Cette commande est destinée à préparer l'évolution de vos applications vers les prochaines versions majeures de 4D. En effet, le format "PICT" Mac a été déclaré obsolète par Apple depuis de nombreuses versions de Mac OS (voir la description du format PICT sur Wikipedia). Il est conservé dans 4D par soucis de compatibilité mais ne sera plus pris en charge compter de 4D v14. Pour anticiper la migration de vos applications, vous pouvez dès à présent utiliser cette commande afin de détecter toutes les images PICT de votre base et les convertir en un format natif (par exemple PNG) à l'aide de la commande CONVERTIR IMAGE. A noter qu'une fois convertie dans un format, l'image ne contient plus que ce format.

Note : La suppression du format PICT nécessite une analyse préalable dans le cas d'images destinées à l'impression. Le format PICT étant un format vectoriel, il peut être utilisé en particulier sous Windows pour l'impression, lorsqu'il est présent. Dans ce contexte, il est alors préférable de convertir les images PICT vers un format vectoriel, par exemple EMF.

Exemple

Vous souhaitez tester et convertir si nécessaire toutes les images de la bibliothèque :

 C_ENTIER LONG($vlImage;$vlNbImages;$vlRefImage;$vltotal)

 C_TEXTE($vsNomImage)

 C_POINTEUR($vPointeur)

 C_IMAGE($vgImage)

 TABLEAU TEXTE($asNomImage;0)

 TABLEAU ENTIER LONG($alRefImage;0)

 

 $vltotal:=0

 LISTE IMAGES DANS BIBLIOTHEQUE($alRefImage;$asNomImage)

 $vlNbImages:=Taille tableau($alRefImage)

 Si($vlNbImages>0)

    Boucle($vlImage;1;$vlNbImages)  // pour chaque image

       $vlRefImage:=$alRefImage{$vlImage}

       $vsNomImage:=$asNomImage{$vlImage}

       LIRE IMAGE DANS BIBLIOTHEQUE($alRefImage{$vlImage};$vgImage)

       $vPointeur:=->$vgImage  // passage d''un pointeur

       $isobs:=AP Is Picture Deprecated($vPointeur)

       Si($isobs=1)  // si format obsolète

          CONVERTIR IMAGE($vPointeur->;".PNG")  // conversion en png

            // et stockage dans la bibliothèque

          ECRIRE IMAGE DANS BIBLIOTHEQUE($vPointeur->;$vlRefImage;$vsNomImage)

          $vltotal:=$vltotal+1

       Fin de si

    Fin de boucle

    ALERTE(Chaine($vltotal)+" image(s) sur "+Chaine($vlNbImages)+" ont été converties en png.")

 Sinon

    ALERTE("La bibliothèque d'images est vide.")

 Fin de si