4D Doc Center : AP Is Picture Deprecated

4D Pack v14

AP Is Picture Deprecated


AP Is Picture Deprecated ( ptrPict ) -> Resultado

Parámetro	Tipo	Descripción
ptrPict	Puntero	Puntero al campo o la variable imagen a probar
Resultado	Entero largo	0 = formato válido, 1 = formato obsoleto (PICT)

Descripción

El comando AP Is Picture Deprecated devuelve 1 si la imagen referenciada por el parámetro ptrPict contiene el formato PICT (obsoleto) PICT y 0 en caso contrario. Una imagen será considerada obsoleta si está en formato PICT o si contiene el formato PICT (imágenes insertadas por arrastrar soltar pueden incluir varios formatos).

En ptrPict, pase un puntero al campo imagen, la variable imagen o el elemento de array imagen 4D a probar.

Este comando tiene la intención de preparar el desarrollo de sus aplicaciones para las próximas versiones principales de 4D. De hecho, el formato "PICT" Mac fue declarado obsoleto por Apple desde varias versiones atrás de Mac OS (ver la descripción del formato PICT en Wikipedia). Se mantuvo en 4D por razones de compatibilidad, pero que ya no es compatible a partir de 4D v14. Para prepararse para la migración de sus aplicaciones, puede comenzar a usar este comando con el fin de detectar todas las imágenes PICT en su base y convertirlas a un formato nativo (por ejemplo PNG) con ayuda del comando CONVERT PICTURE. Tenga en cuenta que una vez convertidas a un formato, las imágenes sólo contienen este nuevo formato.

Nota: la eliminación del formato PICT requiere de un análisis previo en el caso de las imágenes destinadas a la impresión. El formato PICT es un formato vectorial, puede ser utilizado en particular bajo Windows para impresión, cuando está presente. Así, en este contexto, es preferible convertir las imágenes PICT a otro formato vectorial, por ejemplo EMF.

Ejemplo

Usted quiere probar y convertir todas las imágenes de la librería:

 C_LONGINT($vlPict;$vPictCount;$vPictRef;$vTotal)

 C_TEXT($vPictName)

 C_POINTER($vPointer)

 C_PICTURE($vpPict)

 ARRAY TEXT($arrPictNames;0)

 ARRAY LONGINT($arrPictRefs;0)

 

 $vTotal:=0

 PICTURE LIBRARY LIST($arrPictRefs;$arrPictNames)

 $vPictCount:=Size of array($arrPictRefs)

 If($vPictCount>0)

    For($vlPict;1;$vPictCount) // para cada imagen

       $vPictRef:=$arrPictRefs{$vlPict}

       $vPictName:=$arrPictNames{$vlPict}

       GET PICTURE FROM LIBRARY($arrPictRefs{$vlPict};$vpPict)

       $vPointer:=->$vpPict  // pass a pointer

       $isObs:=AP Is Picture Deprecated($vPointer)

       If($isObs=1) // if format is obsolete

          CONVERT PICTURE($vPointer->;".PNG") // conversión a png

  // y guardar en la librería

          SET PICTURE TO LIBRARY($vPointer->;$vPictRef;$vPictName)

          $vTotal:=$vTotal+1

       End if

    End for

    ALERT(String($vTotal)+" picture(s) out of "+String($vPictCount)+" were converted to png.")

 Else

    ALERT("La librería de imágenes está vacía")

 End if