WP FIXER ATTRIBUTS

4D v20

WP FIXER ATTRIBUTS


WP FIXER ATTRIBUTS ( objCible ; nomAttribut ; valeurAttribut {; nomAttribut2 ; valeurAttribut2 ; ... ; nomAttributN ; valeurAttributN} )

Paramètre	Type	Description
objCible	Objet	Plage ou élément ou document 4D Write Pro
nomAttribut	Texte	Nom d'attribut dont vous souhaitez fixer la valeur
valeurAttribut	Texte, Numérique, Objet, Collection, Image, Date	Nouvelle valeur de l'attribut

Description

La commande WP FIXER ATTRIBUTS vous permet de fixer la valeur d'un ou plusieurs attribut(s) dans une plage, un élément ou un document 4D Write Pro. Cette commande donne accès à tous les types d'attributs internes de 4D Write Pro : caractère, paragraphe, tableau, document ou image.

Dans objCible, vous pouvez passer :

un objet plage 4D Write Pro, ou
un élément (en-tête / pied / corps / tableau / ligne / image en ligne ou ancrée / paragraphe / section / sous-section / feuille de style), ou
un document 4D Write Pro.

Dans nomAttribut, passez le nom de l'attribut à modifier pour la cible et dans valeurAttribut, passez la valeur à définir. Pour une liste complète des attributs que vous pouvez passer dans nomAttribut ainsi que les valeurs que vous pouvez passer dans valeurAttribut, veuillez vous référer à la section Attributs 4D Write Pro.

Vous pouvez passer autant de paires nomAttribut / valeurAttribut que vous voulez.

Note : Si vous devez définir plusieurs attributs pour la même cible, il est plus optimisé d'effectuer un appel unique à WP FIXER ATTRIBUTS avec toutes les paires attributs/valeurs, que d'appeler plusieurs fois WP FIXER ATTRIBUTS.

Exemple 1

Dans cette zone 4D Write Pro, vous sélectionnez un mot :

Si vous exécutez le code suivant :

 $range:=WP Lire selection(*;"WParea") //récupérer la plage sélectionnée

 

  // fixer le décalage d'ombre en pt pour la sélection

 WP FIXER ATTRIBUTS($range;wk text shadow offset;1)

  //définir la marge intérieure du paragraphe

 WP FIXER ATTRIBUTS($range;wk padding;1)

  //définir une bordure de 10 pt

 WP FIXER ATTRIBUTS($range;wk border style;wk solid;wk border width;10)

  //définir les couleurs de bordure

 WP FIXER ATTRIBUTS($range;wk border color;"blue";wk border color bottom;"#00FA9A";wk border color right;"#00FA9A")

Vous obtenez le résultat suivant :

Exemple 2

Cet exemple illustre le rôle des constantes wk inside et wk outside :

 $wpRange:=WP Lire selection(writeProdoc)

 WP FIXER ATTRIBUTS($wpRange;wk border style+wk inside;wk dotted)

 WP FIXER ATTRIBUTS($wpRange;wk border style+wk outside;wk solid)

 WP FIXER ATTRIBUTS($wpRange;wk border color+wk outside;"#00FA9A")

En supposant que tout le contenu était sélectionné, le résultat est :

Exemple 3

Vous souhaitez définir une image de fond pour le document :

 C_OBJET(WParea)

 WParea:=WP Nouveau

 

 LIRE FICHIER IMAGE("C:\\Pictures\\boats.jpg";$picture)

 

 WP FIXER ATTRIBUTS(WParea;wk background image;$picture)

Le résultat est le suivant :

Vous souhaitez définir une image de fond qui recouvre la totalité de la zone d'impression :

 C_OBJET(WParea)

 WParea:=WP Nouveau

 

 LIRE FICHIER IMAGE("C:\\Pictures\\boats.jpg";$picture)

 

 WP FIXER ATTRIBUTS(WParea;wk background image;$picture)

 WP FIXER ATTRIBUTS(WParea;wk background clip;wk paper box)

 WP FIXER ATTRIBUTS(WParea;wk background origin;wk paper box)

Le résultat est le suivant :

Note : La valeur wk paper box peut être appliquée uniquement aux documents ou aux sections.

Exemple 4

Vous souhaitez définir des tabulations à intervalles variés et définir un caractère comme étant le caractère principal pour la différente tabulation :

 $tab1:=Creer objet()

 $tab1[wk type]:=wk left

 $tab1[wk offset]:="3cm"

 $tab1[wk leading]:=""

 

 $tab2:=Creer objet()

 $tab2[wk type]:=wk center

 $tab2[wk offset]:="8cm"

 $tab2[wk leading]:=""

 

 $tab3:=Creer objet()

 $tab3[wk type]:=wk right

 $tab3[wk offset]:="12cm"

 $tab3[wk leading]:="."

 

 $_tabs:=Creer collection($tab1;$tab2;$tab3)

 WP FIXER ATTRIBUTS(wpArea;wk tabs;$_tabs)

Le résultat est du type :

Voir aussi

Attributs 4D Write Pro
WP LIRE ATTRIBUTS
WP REINITIALISER ATTRIBUTS