OB FIXER TABLEAU

4D v20.1

OB FIXER TABLEAU


OB FIXER TABLEAU ( objet ; propriété ; tableau )

Paramètre	Type	Description
objet	Champ objet, Objet	Objet structuré
propriété	Texte	Nom de la propriété à définir
tableau	Tableau, Variable	Tableau à stocker dans la propriété

Description

La commande OB FIXER TABLEAU permet de définir le tableau à associer à la propriété dans l’objet de langage désigné par le paramètre objet.

objet doit avoir été défini via la commande C_OBJET ou désigner un champ objet 4D.

Passez dans le paramètre propriété le libellé de la propriété à créer ou à modifier. Si la propriété existe déjà dans objet, sa valeur sera mise à jour. Si elle n’existe pas, elle est créée. Attention, le paramètre propriété tient compte des majuscules/minuscules.

Passez dans le paramètre tableau le tableau devant être passé comme valeur de la propriété. Plusieurs types de tableaux sont pris en charge : réel, entier long, texte, booléen, objet, pointeur ou image.

Notes :

Les variables simples sont prises en charge dans le paramètre tableau, auquel cas un tableau à valeur unique est créé et associé à la propriété.
Il n’est pas possible d’utiliser de tableaux à deux dimensions.

Exemple 1

Utilisation d’un tableau texte :

 C_OBJET($Children)

 TABLEAU TEXTE($tabChildren;3)

 $tabChildren{1}:="Richard"

 $tabChildren{2}:="Susan"

 $tabChildren{3}:="James"

 

 OB FIXER TABLEAU($Children;"Children";$tabChildren)

     // Valeur de $Children = {"Children":["Richard","Susan","James"]}

Exemple 2

Ajout d’un élément dans un tableau :

 TABLEAU TEXTE($tabText;2)

 $tabText{1}:="Smith"

 $tabText{2}:="White"

 C_OBJET($Employees)

 OB FIXER TABLEAU($Employees;"Employés";$tabText)

 AJOUTER A TABLEAU($tabText;"Brown") //Ajout dans le tableau 4D

     // $Employees = {"Employés":["Smith","White"]}

 

 OB FIXER TABLEAU($Employees;"Employés";$tabText)

     // $Employees = {"Employés":["Smith","White","Brown"]}

Exemple 3

Utilisation d’un tableau texte avec sélection d’un élément :

     //$Employees = {"Employés":["Smith","White","Brown"]}

 OB FIXER TABLEAU($Employees ;"Manager";$tabText{1})

     //$Employees = {"Employees":["Smith","White","Brown"],"Manager":["Smith"]}

Exemple 4

Utilisation d’un tableau objet :

 C_OBJET($Enfants;$ref_richard;$ref_susan;$ref_james)

 TABLEAU OBJET($tabEnfants;0)

 OB FIXER($ref_richard;"nom";"Richard";"age";7)

 AJOUTER A TABLEAU($tabEnfants;$ref_richard)

 OB FIXER($ref_susan;"nom";"Susan";"age";4)

 AJOUTER A TABLEAU($tabEnfants;$ref_susan)

 OB FIXER($ref_james;"nom";"James";"age";3)

 

 AJOUTER A TABLEAU($tabEnfants;$ref_james)

 

     //$tabEnfants {1} = {"nom":"Richard","age":7}

     //$tabEnfants {2} = {"nom":"Susan","age":4}

     //$tabEnfants {3} = {"nom":"James","age":3}

 

 OB FIXER TABLEAU($Enfants;"Enfants";$tabEnfants)

 

     // $Enfants = {"Enfants":[{"nom":"Richard","age":7},{"nom":"Susan",

     // "age":4},{"nom":"James","age":3}]}

L’objet est représenté ainsi dans le débogueur :

Exemple 5

Utilisation d'un champ objet :

 TABLEAU TEXTE($arrGirls;3)

 $arrGirls{1}:="Emma"

 $arrGirls{2}:="Susan"

 $arrGirls{3}:="Jamie"

 OB FIXER TABLEAU([Personnes]Enfants;"Girls";$arrGirls)

Exemple 6

Using a picture array:

 ARRAY PICTURE($arrPhotos;3)

 READ PICTURE FILE("pict1.jpg";$arrPhotos{1})

 READ PICTURE FILE("pict2.jpg";$arrPhotos{2})

 READ PICTURE FILE("pict3.jpg";$arrPhotos{3})

 

 OB SET ARRAY([Cities]Places;"Photoset";$arrPhotos)

Voir aussi

Conversions de type entre les collections et les tableaux 4D
OB FIXER
OB LIRE TABLEAU