ARRAY TO COLLECTION

Home

4D v20.1

ARRAY TO COLLECTION


ARRAY TO COLLECTION ( Collection ; Array {; EigenschaftenName}{; Array2 ; EigenschaftenName2 ; ... ; ArrayN ; EigenschaftenNameN} )

Parameter	Typ	Beschreibung
Collection	Collection	Collection zum Empfangen der Daten des Array
Array	Array	Array zum Kopieren in die Collection; ist EigenschaftenName übergeben, Array zum Kopieren in die Werte von EigenschaftenName in der Collection
EigenschaftenName	Text	Name der Objekteigenschaft, deren Wert mit Array Elementen gefüllt werden soll.

Beschreibung

Der Befehl ARRAY TO COLLECTION kopiert ein oder mehrere Array(s) in die Elemente oder die Werte EigenschaftenName von Collection.

ARRAY TO COLLECTION arbeitet mit einer Collection mit Werten, oder mit einer Collection mit Objekten. Im zweiten Fall sind der/die Parameter EigenschaftenName zwingend.

Ohne den Parameter EigenschaftenName kopiert der Befehl alle Elemente von Array in Collection. Ist Collection nicht leer, werden vorhandene Elemente ersetzt und neue Elemente hinzugefügt, wenn Array größer als die Länge von Collection ist. Anschließend ist die Länge von Collection identisch mit der Größe von Array.
Übergeben Sie einen oder mehrere Parameter EigenschaftenName, erstellt oder ersetzt der Befehl Objekte als Elemente von Collection. Jedes Objekt wird mit einer Eigenschaft mit dem Namen, übergeben im Parameter EigenschaftenName, und dem Wert des entsprechenden Array Elements gefüllt. Ist Collection nicht leer, werden vorhandene Elemente ersetzt und neue Elemente hinzugefügt, wenn Array größer als die Collection ist. Anschließend entspricht die Länge von Collection dem größten Array.

Beispiel 1

Ein Text Array in eine Collection kopieren:

 C_COLLECTION($colFruits)

 $colFruits:=New collection

 ARRAY TEXT($artFruits;4)

 $artFruits{1}:="Orange"

 $artFruits{2}:="Banane"

 $artFruits{3}:="Apfel"

 $artFruits{4}:="Traube"

 ARRAY TO COLLECTION($colFruits;$artFruits)

  //$colFruits[0]="Orange"

  //$colFruits[1]="Banane"

  //...

Beispiel 2

Feldwerte in einer Collection von Objekten über Arrays kopieren:

 C_COLLECTION($col)

 $col:=New collection

 ARRAY TEXT($artCity;0)

 ARRAY LONGINT($arLZipCode;0)

 SELECTION TO ARRAY([Customer]City;$artCity)

 SELECTION TO ARRAY([Customer]Zipcode;$arLZipCode)

 ARRAY TO COLLECTION($col;$artCity;"cityName";$arLZipCode;"Zip")

  //$col[0]={"cityName":"Cleveland","Zip":35049}

  //$col[1]={"cityName":"Blountsville","Zip":35031}

  //...

Beispiel 3

Ein Text Array in eine shared Collection kopieren:

 ARRAY TEXT($at;1)

 

 APPEND TO ARRAY($at;"Apple")

 APPEND TO ARRAY($at;"Orange")

 APPEND TO ARRAY($at;"Grape")

 

 C_COLLECTION($sharedCol)

 $sharedCol:=New shared collection

 

 Use($sharedCol)

    ARRAY TO COLLECTION($sharedCol;$at)

 End use

Siehe auch

COLLECTION TO ARRAY
Typkonvertierung zwischen Collections und 4D Arrays