entitySelection.extract( )

4D v19

Descrição

O método entitySelection.extract( ) retorna uma coleção contendo valores propriedadeRota extraídos da seleção de entidades.

propriedadeRota podem referir a:

um atributo de classe de dados escalar,
entidade relacionada,
entidades relacionadas.

Se propriedadeRota é inválida, uma coleção vazia é retornada.

Este método aceita duas sintaxes.

entitySelection.extract ( propertyPath {; option}) -> collection

With this syntax, entitySelection.extract( ) populates the returned collection with the propertyPath values of the entity selection.

By default, entities for which propertyPath is null or undefined are ignored in the resulting collection. You can pass the ck keep null constant in the option parameter to include these values as null elements in the returned collection.

Dataclass attributes with dataClassAttribute.kind = "relatedEntity" are extracted as a collection of entities (duplications are kept).
Dataclass attributes with dataClassAttribute.kind = "relatedEntities" are extracted as a collection of entity selections.

entitySelection.extract ( propertyPath ; targetPath {propertyPath2 ; targetPath2 ;...; propertyPathN ; targetPathN}) -> collection

With this syntax, entitySelection.extract( ) populates the returned collection with the propertyPath properties. Each element of the returned collection is an object with targetPath properties filled with the corresponding propertyPath properties. Null values are kept (option parameter is ignored with this syntax).

If several propertyPath are given, a targetPath must be given for each. Only valid pairs [propertyPath, targetPath] are extracted.

Dataclass attributes with dataClassAttribute.kind = "relatedEntity" are extracted as an entity.
Dataclass attributes with dataClassAttribute.kind = "relatedEntities" are extracted as an entity selection.

Note: Entities of a collection of entities accessed by [ ] are not reloaded from the database.

Exemplo

Dada a tabela abaixo e relação:

 C_COLLECTION($firstnames;$addresses;$mailing;$teachers)

 C_OBJECT($status)

  //

  //

  //$firstnames é uma coleção de String

 $firstnames:=ds.Teachers.all().extract("firstname")

  //

  //$addresses é uma coleção de entidades relacionadas à classe de dados Address

  //Valores Null para endereços são extraídos

 $addresses:=ds.Teachers.all().extract("address";ck keep null)

  //

  //

  //$mailing é uma coleção de objetos com propriedades "who" e "to"

  //conteúdo da propriedade "who" é tipo  String

  //conteúdo da propriedade "to" é tipo entidade (classe de dados Address)

 $mailing:=ds.Teachers.all().extract("lastname";"who";"address";"to")

  //

  //

  //$mailing é uma coleção de objetos com propriedades "who" e "city"

  //conteúdo da propriedade "who" é tipo String

  //conteúdo da propriedade "city" é tipo String

 $mailing:=ds.Teachers.all().extract("lastname";"who";"address.city";"city")

  //

  //$teachers é uma coleção de objetos com propriedades "where" e "who"

  //conteúdo propriedade "where" é String

  //conteúdo propriedade "who" é uma seleção de entidade (classe de dados Teachers)

 $teachers:=ds.Address.all().extract("city";"where";"teachers";"who")

  //

  //$teachers é uma coleção de seleção de entidades

 $teachers:=ds.Address.all().extract("teachers")

Ver também

collection.extract( )