dataClass.getInfo( )

4D v19

Description

La méthode dataClass.getInfo( ) retourne un objet qui fournit des informations sur la dataclass. Cette méthode est utile pour créer le code générique.

Objet retourné

Propriété	Type	Description
name	chaîne	Nom de la dataclass
primaryKey	chaîne	Nom de la clé primaire de la dataclass
tableNumber	numérique	Numéro interne de la table 4D (non retourné si la dataclass provient d'un datastore distant)

Exemple 1

 C_OBJET($1;$e;$status)

 $e:=$1 //$1 est une entité

 

 computeEmployeeNumber($e) //Exécuter des actions sur une entité

 

 $status:=$e.save()

 Si($status.success)

    ALERTE("Enregistrement mis à jour dans la table "+$e.getDataClass().getInfo().name)

 Fin de si

Exemple 2

 C_OBJET($es;$settings)

 

 $settings:=Creer objet

 $settings.parameters:=Creer objet("receivedIds";getIds())

 $settings.attributes:=Creer objet("pk";ds.Clients.getInfo().primaryKey)

 $es:=ds.Clients.query(":pk in :receivedIds";$settings)

Exemple 3

 C_TEXTE($pk)

 C_OBJET($dataClassAttribute)

 

 $pk:=ds.Employee.getInfo().primaryKey

 $dataClassAttribute:=ds.Employee[$pk] // Le cas échéant, l'attribut correspondant à la clé primaire est accessible

Voir aussi

dataStore.getInfo( )
entitySelection.getDataClass( )