Element Null eines Array verwenden

Home

4D v19

Ein Array hat immer ein Element Null. Es erscheint zwar nicht in einem Array für ein Formularobjekt, es kann jedoch fast uneingeschränkt in der Programmiersprache eingesetzt werden.
Ausnahme: In einem Array vom Typ Listbox wird das Element Null intern zum Speichern des vorigen Wertes eines Elements in Bearbeitung verwendet. Sie können es also in diesem spezifischen Kontext nicht verwenden.

Ein Beispiel dafür haben Sie bereits im Abschnitt Arrays und Formularobjekte unter Combo Boxen gesehen. Hier folgt ein weiteres Beispiel:

Eine bestimmte Aktion soll nur ausgeführt werden, wenn ein anderes Element als das zuvor gewählte angeklickt wird. Dazu müssen Sie jedes ausgewählte Element verfolgen. Dazu könnten Sie eine Prozessvariable mit der Elementnummer des ausgewählten Elements einsetzen oder wie nachfolgend beschrieben, das Element Null:

  ` Objektmethode rollbarer Bereich atNames

 Case of

    :(Form event code=On Load)

  ` Initialisiere das Array (wie bereits oben gezeigt)

       ARRAY TEXT(atNames;5)

  ` ...

  ` Initialisiere das Element Null mit der Nummer des gerade ausgewählten

  ` Elements im Texformular

  ` Hier starten Sie mit keinem ausgewählten Element

       atNames{0}:="0"

 

    :(Form event code=On Unload)

  ` Wir benötigen das Array nicht mehr

       CLEAR VARIABLE(atNames)

 

    :(Form event code=On Clicked)

       If(atNames#0)

          If(atNames#Num(atNames{0}))

             vtInfo:="Sie haben geklickt auf: "+atNames{atNames}+" und es wurde vorher noch nicht ausgewählt."

             atNames{0}:=String(atNames)

          End if

       End if

    :(Form event code=On Double Clicked)

       If(atNames#0)

          ALERT("Sie haben doppelgeklickt auf: "+atNames{atNames}

       End if

 End case

Siehe auch

Einführung in Arrays