Compare strings

4D v19

Compare strings


Compare strings ( aString ; bString {; options} ) -> Résultat

Paramètre	Type	Description
aString	Chaîne	Chaîne à comparer
bString	Chaîne	Chaîne à comparer
options	Entier long	Règle(s) de comparaison
Résultat	Entier long	Résultat de la comparaison de chaînes

Description

La commande Compare strings retourne une valeur négative, zéro, ou une valeur positive, en fonction du paramètre aString selon qu'il soit évalué comme étant inférieur, égal ou supérieur au paramètre bString.

Dans le paramètre aString, passez une valeur texte.

Dans le paramètre aString, passez une valeur texte à comparer avec aString.

Par défaut, Compare strings fonctionne comme si l'opérateur "<" (inférieur à) était utilisé. (Voir Opérateurs de chaînes). Cela peut être modifié à l'aide du paramètre options. Vous pouvez passer une ou plusieurs des constantes du thème Chaînes :

Constante	Valeur	Comment
sk case insensitive	2	Les chaînes sont comparées en fonction de la langue des données, indépendamment des différences de capitalisation. A noter que les signes diacritiques sont pris en compte. Par exemple, "A" est considéré comme identique à "a", mais "a" n'est pas considéré comme identique à "à". Peut être combinée avec : sk char codes sk diacritic insensitive sk kana insensitive sk strict sk whole word (commande Position uniquement)
sk char codes	1	Les chaînes sont comparées en fonction des codes de caractères. Les paramètres de langue des données ne sont pas pris en compte lors de la comparaison. Peut être combinée avec : sk case insensitive Uniquement pour les plages "a-z" ou "A-Z" ranges. (ex : Alpha = alpha, mais Alpha # âlphà)
sk diacritic insensitive	4	Les chaînes sont comparées en fonction de la langue des données, mais le signe diacritique (par exemple, un accent ou un symbole) des lettres est ignoré. Par exemple, "a" est considéré comme identique à "à". Peut être combinée avec : sk case insensitive sk kana insensitive sk strict sk width insensitive sk whole word (commande Position uniquement)
sk kana insensitive	8	S'applique à la langue japonaise. Les chaînes sont comparées en fonction de la signification (et non du style d'écriture) dans la langue des données. Par exemple, "あ" est considéré comme identique à "ア". Lorsque cette option est définie, sk width insensitive est implicite (considérée comme définie), mais l'inverse n'est pas vrai. Peut être combinée avec : sk case insensitive sk diacritic insensitive sk strict sk width insensitive
sk strict	0	Les chaînes sont comparées pour les correspondances exactes en fonction de la langue actuelle des données. Dans la plupart des cas, les majuscules et les signes diacritiques des lettres sont pris en compte lors de la comparaison. Peut être combinée avec : sk case insensitive sk diacritic insensitive sk kana insensitive sk width insensitive
sk width insensitive	16	S'applique à la langue japonaise. Les chaînes sont comparées par largeur de caractère en fonction de la langue des données. Par exemple, "ｱ" est considéré comme identique à "ア". Peut être combinée avec : sk case insensitive sk diacritic insensitive sk kana insensitive sk strict

Pour plus d'informations sur la définition du langage de données, veuillez consulter la section Comparaison de texte dans le Manuel de Développement.

Attention : Vous ne pouvez pas utiliser le caractère @ avec Compare strings. Par exemple, si vous passez abc@" dans aString ou bString, la commande évaluera la chaîne "abc@" et non une chaîne "abc" accompagnée de tout autre caractère.

Valeur retournée

La commande retourne les valeurs entier long suivantes :

Valeur	Description
-1	aString est inférieur à bString
0	aString est égal à bString
1	aString est supérieur à bString

Exemple 1

Vous souhaitez comparer les chaînes suivantes :

 $string1:="alpha Bravo charlie Delta Echo Fox-Trot"

 $string2:="Alpha Bravo Charlie Delta Echo Fox-Trot"

 

  //comparer les chaînes à l'aide du code caractère

 $result:=Compare strings($string1;$string2;sk char codes)

  // $result = 1

 

  //comparer les chaînes à l'aide du code caractère mais en ignorant les majuscules

 $result:=Compare strings($string1;$string2;sk char codes+sk case insensitive)

  // $result = 0

Exemple 2

Les exemples suivants illustrent l'incidence des options dans le contexte de la langue de données japonaise :

  //par défaut, kana insensible à la casse

 $result:=Compare strings("イロハ";"いろは") // identique

 $result:=Compare strings("イロハ";"いろは";sk strict) // non identique

 $result:=Compare strings("イロハ";"いろは";sk kana insensitive) // identique

  //par défaut, insensible à la casse

 $result:=Compare strings("さつき";"さっき") // identique

 $result:=Compare strings("さつき";"さっき";sk strict) // non identique

 $result:=Compare strings("さつき";"さっき";sk case insensitive) // identique

  //par défaut, sensible aux signes diacritiques lorsque la langue des données est définie sur le japonais (différente de toutes les autres langues)

 $result:=Compare strings("ete";"été") // identique dans une langue de données autre que le japonais

 $result:=Compare strings("ete";"été") // non identique en langue de données japonaise

 $result:=Compare strings("うがい";"うかい") // non identique

 $result:=Compare strings("うがい";"うかい";sk strict) // non identique

 $result:=Compare strings("うがい";"うかい";sk diacritic insensitive) // identique

Note : Le paramètre "Ordre de tri approprié pour la recherche" (voir Comparaison de texte) a une incidence sur la commande Compare strings. En particulier, la "Marque sonore prolongée Katakana-Hiragana" ou "長音記号" sera interprétée différemment. Le paramètre a également une incidence sur les « marques d'itération japonaises » telles que « ゝ » ou « ゞ ». Par exemple :

 $result:=Compare strings("いすず";"いすゞ") // identique si le paramètre est désactivé

 $result:=Compare strings("いすず";"いすゞ") // non identique si le paramètre est activé

 $result:=Compare strings("ラーメン";"ﾗｰﾒﾝ") //  identique si le paramètre est activé

 $result:=Compare strings("ラーメン"; "ﾗｰﾒﾝ") // non identique si le paramètre est désactivé

Voir aussi

Position