entity.lock( )

4D v18

entity.lock( )

説明

entity.lock( ) メソッドはデータクラスにリレートされたデータストアとテーブル内のエンティティに合致するレコードにペシミスティック・ロック(*)をかけます。ロックはレコードと、カレントプロセス内でのエンティティの全ての参照に対してかけられます。

(*)詳細な情報については、エンティティロッキングのページを参照してください。

他のプロセスからはこのレコードはロックされて見えます(このメソッドを使って同じエンティティをロックしようとした場合、result.success プロパティにはfalseが返されます)。"locking"セッション内で実行されたメソッドのみがこのエンティティの属性を編集・保存できます。エンティティは他のセッションによって読み込みのみでロードすることもできますが、値の入力・保存はできません。

ロックされたレコードは、以下の場合にロックが解除されます:

同じプロセス内で合致するエンティティに対してunlock() メソッドが呼び出された場合
メモリ内からどのエンティティからも参照されなくなった場合、自動的にロックが解除されます。例えば、エンティティのローカル参照に対してのみロックがかかっていた場合、メソッドが終了すればエンティティのロックは解除されます。メモリ内にエンティティへの参照がある限り、レコードはロックされたままです。

mode 引数が省略された場合、デフォルトで、同じエンティティが他のプロセスあるいはユーザーから同時に変更された(例: スタンプが変更された)場合、メソッドはエラーを返します(以下参照)。
あるいは、mode 引数にはdk reload if stamp changed オプションを渡すことができます。この場合、スタンプが変更された場合でもエラーは返されず、エンティティは再読み込みされます(エンティティが引き続き存在し、プライマリーキーが引き続き同じであった場合)。

結果オブジェクト

entity.lock( ) によって返されたオブジェクトには、以下のプロパティが含まれます:

プロパティ		型	詳細
success		ブール	ロックアクションが成功した場合(あるいはエンティティがすでにカレントプロセスでロックされていた場合)にはtrue、それ以外の場合にはfalse
			*dk reload if stamp changed オプションが使用されていた場合にのみ利用可能:*
wasReloaded		ブール	エンティティのリロードが成功した場合にはtrue、それ以外の場合にはfalse
			*エラーの場合にのみ利用可能:*
status(*)		数値	エラーコード、以下参照
statusText(*)		テキスト	エラーの詳細、以下参照
			*ペシミスティック・ロックエラーの場合にのみ利用可能:*
lockKindText		テキスト	"Locked by record"
lockInfo		object	ロックの元についての情報
	task_id	数値	プロセスID
	user_name	テキスト	マシン上でのセッションユーザー名
	user4d_alias	テキスト	4D ユーザーの名前またはエイリアス
	user4d_id	数値	4DデータベースディレクトリでのユーザーID
	host_name	テキスト	マシン名
	task_name	テキスト	プロセス名
	client_version	テキスト
			深刻なエラーの場合にのみ利用可能(深刻なエラーとは、プライマリーキーを重複させようとした、ディスクがいっぱいであった、などです):
errors		オブジェクトのコレクション
	message	テキスト	エラーメッセージ
	component signature	テキスト	内部コンポーネント署名(例 "dmbg" はデータベースコンポーネントを表します)
	errCode	数値	エラーコード

(*) エラー時にはResult オブジェクトのstatus あるいは statusText プロパティに以下のいずれかの値が返されます:

定数	値	コメント
dk status entity does not exist anymore	5	エンティティはもうデータ内に存在していません。このエラーは以下のような場合に起き得ます: エンティティがドロップされている(スタンプは変更されていて、メモリ空間は解放されている) エンテイィ亭はドロップされていて、他のプライマリーキー値を持っているもので置き換えられている(スタンプは変更されていて、新しいエンティティがメモリ空間を使用している)。entity.drop( )を使用している場合、このエラーはdk force drop if stamp changed オプションを使用した場合に返される場合があります。entity.lock( )を使用している場合、このエラーはdk reload if stamp changed オプションを使用した場合に返される場合があります。割り当てられたstatusText: "エンティティはもう存在しません"
dk status locked	3	エンティティはペシミスティック・ロックでロックされています。割り当てられたstatusText: "既にロックされています"
dk status serious error	4	深刻なエラーとは低レベルのデータベースエラー(例:重複キーなど)、ハードウェアエラーなどです。割り当てられたstatusText: "その他のエラー"
dk status stamp has changed	2	エンティティの内部的なスタンプ値がデータ内に保存されているエンティティのものと合致しません(オプティミスティック・ロック)。 entity.save( ) の場合: dk auto merge オプションが使用されていない場合に限りエラー entity.drop( ) の場合: dk force drop if stamp changed オプションが使用されていない場合に限りエラー entity.lock( ) の場合: dk reload if stamp changed オプションが使用されていない場合に限りエラー割り当てられたstatusText: "スタンプが変更されています"

例題 1

エラーのある例題:

 C_OBJECT($employee;$status)

 $employee:=ds.Employee.get(716)

 $status:=$employee.lock()

 Case of

    :($status.success)

       ALERT("You have locked "+$employee.firstName+" "+$employee.lastName)

    :($status.status=dk status stamp has changed)

       ALERT($status.statusText)

 End case

例題 2

dk reload if stamp changed オプションを使用した場合を考えます:

 C_OBJECT($employee;$status)

 

 $employee:=ds.Employee.get(717)

 $status:=$employee.lock(dk reload if stamp changed)

 Case of

    :($status.success)

       ALERT("You have locked "+$employee.firstName+" "+$employee.lastName)

    :($status.status=dk status entity does not exist anymore)

       ALERT($status.statusText)

 End case

参照

entity.unlock( )