entity.drop( )

4D v18

entity.drop( )

Description

La méthode entity.drop( ) supprime les données de l'entité de la table associée à la dataclass. A noter que l'entité reste en mémoire.

Dans une application multiprocess ou multi-utilisateurs, la méthode entity.drop( ) est exécutée en mode "verrouillage optimiste", dans lequel un marqueur de verrouillage interne est automatiquement incrémenté à chaque sauvegarde de l'enregistrement. Pour plus d'informations, veuillez vous reporter à la page Verrouillage d'entités.

Par défaut, lorsque le paramètre mode est omis, la méthode retourne une erreur (cf. ci-dessous) si l'entité a été modifiée (i.e. le marqueur interne a changé) entre-temps par un autre process ou utilisateur.
Sinon, vous pouvez passer l'option dk force drop if stamp changed dans le paramètre mode : dans ce cas, l'entité est supprimée même si la valeur du marqueur interne est différente (si la clé primaire est identique).

Résultat

L'objet retourné par entity.drop( ) contient les propriétés suivantes :

Propriété		Type	Description
success		booléen	Vrai si l'action de suppression a été effectuée avec succès, sinon Faux.
			Disponible uniquement en cas d'erreur :
status(*)		numérique	Code d'erreur, voir ci-dessous
statusText(*)		texte	Description de l'erreur, voir ci-dessous
			Disponible uniquement en cas d'erreur de verrouillage pessimiste :
LockKindText		texte	"Locked by record"
lockInfo		objet	Information sur l'origine du verrouillage
	task_id	numérique	ID du process
	user_name	texte	Nom d'utilisateur de la session sur la machine
	user4d_id	texte	Nom d'utilisateur 4D dans le répertoire de la base
	host_name	texte	Nom de la machine
	task_name	texte	Nom du process
	client_version	texte
			Disponible uniquement en cas d'erreur critique (clé primaire dupliquée, disque plein...) :
errors		collection d'objets
	message	texte	Message d'erreur
	component signature	texte	Signature du composant interne (p.e. "dmbg" pour le composant de base de données)
	errCode	nombre	Code d'erreur

(*) Les valeurs suivantes peuvent être retournées dans les propriétés status et statusText de l'objet Résultat en cas d'erreur :

Constante	Valeur	Comment
dk status entity does not exist anymore	5	L'entité n'existe plus dans les données. Cette erreur peut se produire dans les cas suivants : l'entité a été supprimée (le stamp est modifié et l'espace mémoire est libéré) l'entité a été supprimée et remplacée par une autre avec une clé primaire différente (le stamp est modifié et une nouvelle entité occupe l'espace mémoire). Avec entity.drop( ), cette erreur peut être retournée lorsque l'option dk force drop if stamp changed est utilisée. Avec entity.lock( ), cette erreur peut être retournée lorsque l'option dk reload if stamp changed est utilisée. statusText associé : "Entity does not exist anymore"
dk status locked	3	L'entité est verrouillée par un verrou pessimiste. statusText associé : "Already locked"
dk status serious error	4	Une erreur critique peut être une erreur de bas niveau de la base de données (ex. clé dupliquée), une erreur matérielle, etc. statusText associé : "Other error"
dk status stamp has changed	2	La valeur du marqueur interne (stamp) de l'entité ne correspond pas à celle de l'entité stockée dans les données (verrouillage optimiste). avec entity.save( ) : erreur uniquement si l'option dk auto merge n'est pas utilisée avec entity.drop( ) : erreur uniquement si l'option dk force drop if stamp changed n'est pas utilisée avec entity.lock( ) : erreur uniquement si l'option dk reload if stamp changed n'est pas utilisée statusText associé : "Stamp has changed"

Exemple 1

Exemple sans option dk force drop if stamp changed :

 C_OBJET($employees;$employee;$status)

 $employees:=ds.Employee.query("lastName=:1";"Smith")

 $employee:=$employees.first()

 $status:=$employee.drop()

 Au cas ou

    :($status.success)

       ALERTE("Vous avez supprimé "+$employee.firstName+" "+$employee.lastName) //L'entité supprimée reste en mémoire

    :($status.status=dk status stamp has changed)

       ALERTE($status.statusText)

 Fin de cas

Exemple 2

Même exemple avec l'option dk force drop if stamp changed :

 C_OBJET($employees;$employee;$status)

 $employees:=ds.Employee.query("lastName=:1";"Smith")

 $employee:=$employees.first()

 $status:=$employee.drop(dk force drop if stamp changed)

 Au cas ou

    :($status.success)

       ALERTE("Vous avez supprimé "+$employee.firstName+" "+$employee.lastName) //L'entité supprimée reste en mémoire

    :($status.status=dk status entity does not exist anymore)

       ALERTE($status.statusText)

 Fin de cas

Voir aussi

entity.save( )