ds

4D v18

ds


ds {( localID )} -> 戻り値

引数	型	説明
localID	テキスト	参照を取得したいリモートデータストアのローカルID
戻り値	DataStore	新しいデータストア参照

説明

ds コマンドはカレントの4D データベース、または localID で指定したデータベースに合致するデータストアの参照を返します。

localID を省略した (または空の文字列 "" を渡した) 場合には、ローカル4Dデータベース (4D Server のリモートデータベースを開いている場合にはそのデータベース) に合致するデータストアの参照を返します。データストアは自動的に開かれ、dsによって直接利用することができます。

localID パラメーターに、開かれているリモートデータストアのローカルIDを渡すと、その参照を取得できます。このデータストアは、あらかじめカレントデータベース (ホストまたはコンポーネント)によって Open datastore コマンドで開かれている必要があります。このコマンドを使用したときにローカルIDが定義されます。

注: ローカルIDのスコープは、当該データストアを開いた (Open datastore コマンドを使った) データベースです。

localID に合致するデータストアが見つからない場合、コマンドは Null を返します。

ds を使用するためには、データベースが ORDAの必須要件の章で説明されているようにORDA に準拠している必要があります。以下のルールが適用されます:

データストアは単一のプライマリーキーを持つテーブルのみを参照します。プライマリーキーがないテーブル、あるいは複合プライマリーキーがあるテーブルは参照されません。
BLOB 型属性はデータストアでは管理されません。

データストアの実装についての詳細は、データストアの章を参照してください。

例題 1

4D データベースのメインのデータストアを使用している場合を考えます:

$result:=ds.Employee.query("firstName = :1";"S@")

例題 2

 C_OBJECT($connectTo;$frenchStudents;$foreignStudents;$firstFrench;$firstForeign)

 

 $connectTo:=New object("type";"4D Server";"hostname";"192.168.18.11:8044")

 $frenchStudents:=Open datastore($connectTo;"french")

 

 $connectTo.hostname:="192.168.18.11:8050"

 $foreignStudents:=Open datastore($connectTo;"foreign")

  //...

  //...

 $firstFrench:=getFirst("french";"Students")

 $firstForeign:=getFirst("foreign";"Students")

  //getFirst メソッド

  //getFirst(localID;dataclass) -> entity

  // ---------------------

 C_TEXT($dataClassName;$2;$localId;$1)

 C_OBJECT($0)

 

 $localId:=$1

 $dataClassName:=$2

 $0:=ds($localId)[$dataClassName].all().first()

参照

4D環境
 Open datastore