4D v18

Utilizar la cláusula WHERE

Inicio

 
Inicio
4D v18
Manual de SQL
Tutorial
Utilizar la cláusula WHERE

Utilizar la cláusula WHERE  


 

 

Si ahora queremos saber cuántas películas realizadas desde 1960 están en la videoteca.

El código 4D sería:

 C_LONGINT($NoMovies)
 
 $NoMovies:=0
 REDUCE SELECTION([MOVIES];0)
 QUERY([MOVIES];[MOVIES]Year_of_Movie>=1960)
 $NoMovies:=Records in selection([MOVIES])
 ALERT("La videoteca contiene "+String($NoMovies)+" películas realizadas desde 1960")

  • Utilizando el código SQL:

     C_LONGINT($NoMovies)
     
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     Begin SQL
        SELECT COUNT(*)
        FROM MOVIES
        WHERE Year_of_Movie >= 1960
        INTO :$NoMovies;
     End SQL
     ALERT("La videoteca contiene "+String($NoMovies)+" películas realizadas desde 1960")
  • Utilizando los comandos SQL genéricos:

     C_LONGINT($NoMovies)
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     
     SQL LOGIN(SQL_INTERNAL;"";"")
     SQL EXECUTE("SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960";$NoMovies)
     SQL LOAD RECORD(SQL all records)
     SQL LOGOUT
     ALERT("La videoteca contiene "+String($NoMovies)+" películas realizadas desde 1960")
  • Utilizando el comando QUERY BY SQL:

     C_LONGINT($NoMovies)
     
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     QUERY BY SQL([MOVIES];"Year_of_Movie >= 1960")
     $NoMovies:=Records in selection([MOVIES])
     ALERT("La videoteca contiene "+String($NoMovies)+" películas realizadas desde 1960")
  • Utilizando el comando SQL EXECUTE IMMEDIATE:

     C_LONGINT($NoMovies)
     C_TEXT($tQueryTxt)
     
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     $tQueryTxt:="SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960 INTO :$NoMovies;"
     Begin SQL
        EXECUTE IMMEDIATE :$tQueryTxt;
     End SQL
     ALERT("La videoteca contiene "+String($NoMovies)+" películas realizadas desde 1960")

Como en la sección anterior, para probar todos los ejemplos, simplemente lance la base "4D SQL Code Samples" y vaya a la ventana principal. Elija el modo de interrogación del motor de 4D y haga clic en el botón WHERE clause.

anterior
siguiente

 
PROPIEDADES 

Producto: 4D
Tema: Tutorial

 
CONTENIDO DE LA PÁGINA 
 
HISTORIA 

 
ARTICLE USAGE

Manual de SQL ( 4D v18)