Open datastore

4D v18

Open datastore


Open datastore ( infoConexao ; localID ) -> Resultado

Parâmetro	Tipo	Descrição
infoConexao	Objeto	propriedades conexão usadas para alcançar datastore remota
localID	Texto	ID a atribuir ao datastore aberto na aplicação local (obrigatório)
Resultado	Objeto	Objeto Datastore

Descrição

O comando Open datastore conecta a aplicação ao banco de dados 4D identificada pelo parâmetro infoConexao e devolve um objeto datastore correspondente associado ao alias local localID.

O banco de dados infoConexion 4D deve estar disponível como um datastore remoto, ou seja:

seu servidor web deve ser iniciado com http ou https ativado,
sua opção Expose as REST server deve estar marcada (ver Página Web/Ressource REST),
ao menos uma licença cliente deve estar dispoível.

Se não encontrar um banco de dados coincidente, Open datastore devolve Null.

localID é um alias local para a sessão aberta no datastore remoto. Se localID já existir na aplicação, é utilizado. Do contrário, se cria uma nova sessão localID quando se usa o objeto datastore.

Quando abrir a sessão, as seguintes declarações ficam equivalentes e devolvem uma referência no mesmo objeto datastore:

 $myds:=Open datastore(connectionInfo;"myLocalId")

 $myds2:=ds("myLocalId")

  //$myds y $myds2 son equivalentes

Passe em infoConexion um objeto que descreva o datastore remoto ao que queira conectar-se. Pode conter as seguintes propriedades (todas as propriedades são opcionais, exceto o hostname):

Propriedade	Tipo	Descrição
hostname	Texto	Nome ou endereço IP do datastore remoto + ":" + número de porto (o número de porto é obrigatóirio)
user	Texto	Nome de usuário
password	Texto	Senha de usuário
idleTimeout	Inteiro longo	Tempo de espera de sessão de inatividad (em minutos), depois do qual 4D fecha automaticamente a sesão. Se for omitido, o valor predeterminado é 2880 (48h). O valor não pode ser <60 (se passar um valor inferior, o iempo de espera se estabelece em 60). Para mais informação, consulte Fechar sessões.
tls	Booleano	Usar conexão segura (*). Se omitir, false por padrão. Se recomenda utilizar uma conexão segura sempre que seja possível.
type	Texto	Deve ser "4D Server"

(*) Se tls for true, o protocolo HTTPS se utiliza se:

HTTPS estiver ativado no datastore remoto
o porto dado é o porto HTTPS correto configurado nas propriedades do banco de dados
se instalam um certificado válido e uma chave de cifrado privada no banco de dados (ver Instalação e ativação SSL em 4D).
Do contrário, se gera o erro "1610 - Uma petição remota ao host xxx falhou"

Exemplo 1

Conexão a um datastore remoto sem usuário/senha:

 C_OBJECT($connectTo;$remoteDS)

 $connectTo:=New object("type";"4D Server";"hostname";"192.168.18.11:8044")

 $remoteDS:=Open datastore($connectTo;"students")

 ALERT("Este datastore remoto contiene "+String($remoteDS.Students.all().length)+" students")

Exemplo 2

Conexião a um datastore remoto com usuário /senha / timeout / tls:

 C_OBJECT($connectTo;$remoteDS)

 $connectTo:=New object("type";"4D Server";"hostname";"192.168.18.11:4443";"user";"marie";"password";$pwd;"idleTimeout";70;"tls";True)

 $remoteDS:=Open datastore($connectTo;"students")

 ALERT("This remote datastore contains "+String($remoteDS.Students.all().length)+" students")

Exemplo 3

Trabalhando com vários datastores remotos:

 C_OBJECT($connectTo;$frenchStudents;$foreignStudents)

 $connectTo:=New object("hostname";"192.168.18.11:8044")

 $frenchStudents:=Open datastore($connectTo;"french")

 $connectTo.hostname:="192.168.18.11:8050"

 $foreignStudents:=Open datastore($connectTo;"foreign")

 ALERT("They are "+String($frenchStudents.Students.all().length)+" French students")

 ALERT("They are "+String($foreignStudents.Students.all().length)+" foreign students")

Em caso de erro o comando devolve Null. Se não puder acessar o datastore remoto (endereço incorreto, servidor web não iniciado, http e https não habilitados...), se gera o erro 1610 "Uma petição remota ao host XXX falhou". Pode interceptar este erro com um método instalado por ON ERR CALL.

Ver também

Ambiente 4D
ds

4D v18

Open datastore

Open datastore

Descrição

Exemplo 1

Exemplo 2

Exemplo 3

Gestão de erros