OUVRIR BASE

4D v18

OUVRIR BASE


OUVRIR BASE ( cheminFichier )

Paramètre	Type	Description
cheminFichier	Chaîne	Nom ou chemin d'accès complet du fichier de base de données à ouvrir (.4db, .4dc, .4dbase ou .4dlink)

Description

La commande OUVRIR BASE referme la base de données 4D courante et ouvre à la volée la base désignée par le paramètre cheminFichier. Cette commande est utile dans le cadre de tests automatiques, pour rouvrir une base après compilation, ou pour permettre à une application 4D fusionnée de sélectionner le serveur de la base auquel se connecter.

Dans le paramètre filePath, passez le nom le chemin d'accès complet de la base de données à ouvrir. Vous pouvez utiliser un fichier ayant l'une des extensions suivantes :

.4db (fichier de structure interprété),
.4dc (fichier de structure compilé),
.4dbase (package macOS),
.4dproject (fichier de la base projet)
.4dz (fichier de déploiement des bases projets)
.4dlink (fichier de raccourci).

Si vous passez uniquement un nom de fichier, il doit être placé au même niveau que le fichier de structure de la base courante.

Si le chemin d'accès est valide, 4D quitte la base ouverte et ouvre la base spécifiée. En mode monoposte, la Méthode base Sur fermeture de la base refermée et la Méthode base Sur ouverture (ou la Méthode base Sur ouverture connexion serveur) de la base ouverte sont successivement appelées.

Attention : Comme la commande entraîne la fermeture de l'application courant avant d'ouvrir la base spécifiée, il est déconseillé de l'appeler dans la ou dans une méthode appelée par cette méthode base.

La commande est exécutée de manière asynchrone : après son appel, 4D continue d'exécuter le reste de la méthode. Ensuite, l'application se comporte comme si la commande Quitter du menu Fichier avait été sélectionnée : les boîtes de dialogue d'ouverture sont annulées, tous les process ouverts sont tenus de se terminer en moins de dix secondes, etc.

Si le fichier de base cible n'est pas trouvé ou est invalide, une erreur système standard du gestionnaire de fichiers est retournée et 4D ne fait rien.

Exemple 1

OUVRIR BASE("C:\\databases\\Invoices\\Invoices.4db")

Exemple 2

Ce code peut être ajouté à la Méthode base Sur ouverture d'une application monoposte pour choisir un serveur :

 C_TEXTE($xml)

 $xml:="<?xml version=\"1.0\" encoding=\"UTF-8\"?><database_shortcut is_remote=\"true\" server_database_name=\"{databaseName}\" server_path=\"{IP}\"/>"

 $databaseName:="myServer"

 $IP:="192.168.6.7:19813"

 

 Si(Majuscule enfoncee)

    $IP:=Demander("Adresse IP à connecter à "+$databaseName;$IP)

 Sinon

    ok:=1

 Fin de si

 

 Si(ok=1)

    $xml:=Remplacer chaine($xml;"{databaseName}";$databaseName)

    $xml:=Remplacer chaine($xml;"{IP}";$IP)

    C_OBJET($link)

    $link:=Dossier(fk user preferences folder).file("server.4dlink")

    $link.setText($xml)

    OUVRIR BASE($link.platformPath)

 Sinon

    QUITTER 4D

 Fin de si

Voir aussi

Connexion à une base 4D Server