Form

4D v18

Form


Form -> Résultat

Paramètre	Type	Description
Résultat	Objet	Données associées au formulaire courant

Description

La commande Form retourne l'objet associé au formulaire courant, s'il existe. 4D associe automatiquement un objet au formulaire courant dans les cas suivants :

le formulaire courant est affiché par la commande DIALOGUE,
le formulaire courant est un sous-formulaire.

Formulaire DIALOGUE

Si le formulaire courant est affiché suite à un appel à la commande DIALOGUE, Form retourne soit un objet vide, soit l'objet formData passé en paramètre à cette commande, le cas échéant.

Sous-formulaire

Si le formulaire courant est un sous-formulaire, l'objet retourné par Form dépend de la variable du conteneur parent :

Si la variable associée au conteneur parent a été typée en objet (C_OBJET), Form retourne la valeur de cette variable.
Dans ce cas, l'objet retourné par Form est identique à celui retourné par l'expression suivante :
(OBJET Lire pointeur(Objet conteneur sous formulaire))->

Si la variable associée au conteneur parent n'a pas été typée en objet, Form retourne un objet vide, maintenu par 4D dans le contexte du sous-formulaire.

Pour plus d'informations, veuillez vous reporter à la section Sous-formulaires en page.

Exemple

Dans un formulaire affichant l'enregistrement d'une personne, un bouton ouvre un dialogue permettant de vérifier ou de modifier les noms et âges de ses enfants :

Note : Le champ objet "enfants" est représenté uniquement dans cet exemple afin de faire apparaître sa structure.

Dans le formulaire de vérification, vous avez assigné des propriétés d'objet Form aux variables :

Voici le code du bouton "Check Children" :

 C_ENTIER LONG($win;$n;$i)

 C_BOOLEEN($save)

 TABLEAU OBJET($children;0)

 OB LIRE TABLEAU([Person]Children;"children";$children) //récupérer les enfants

 $save:=Faux //initialisation du marqueur de sauvegarde

 

 $n:=Taille tableau($children)

 Si($n>0)

    $win:=Creer fenetre formulaire("Edit_Children";Form dialogue modal déplaçable)

    CHANGER TITRE FENETRE("Vérification des enfants pour "+[Person]Name)

    Boucle($i;1;$n) //pour chaque enfant

       DIALOGUE("Edit_Children";$children{$i}) //afficher le dialogue prérempli

       Si(OK=1) //l'utilisateur a cliqué sur OK

          $save:=Vrai

       Fin de si

    Fin de boucle

    Si($save=Vrai)

       [Person]Children:=[Person]Children //Forcer la mise à jour du champ

    Fin de si

    FERMER FENETRE($win)

 Sinon

    ALERTE("Pas d'enfant à vérifier.")

 Fin de si

Note : Cet exemple nécessite l'activation de la notation objet dans la base (voir Page Compatibilité).

Le formulaire affiche les informations pour chaque enfant :

Si des valeurs sont modifiées et que l'utilisateur clique sur le bouton OK, le champ est mis à jour (bien entendu, l'enregistrement parent devra être sauvegardé par la suite).

Voir aussi

DIALOGUE