Creer objet

4D v18

Creer objet


Creer objet {( propriété ; valeur {; propriété2 ; valeur2 ; ... ; propriétéN ; valeurN} )} -> Résultat

Paramètre	Type	Description
propriété	Texte	Nom de la propriété à créer
valeur	Texte, Date, Booléen, Pointeur, Numérique, Objet	Valeur de la propriété
Résultat	Objet	Nouvel objet structuré

Description

La commande Creer objet crée un objet vide ou pré-rempli et retourne sa référence.

Si vous ne passez aucun paramètre, Creer objet crée un objet vide et retourne sa référence. Vous devez assigner cette référence à une variable 4D déclarée avec C_OBJET ou un champ objet 4D.

Note : C_OBJET déclare une variable de type Objet mais ne crée pas d'objet.

Optionnellement, vous pouvez pré-remplir le nouvel objet en passant une ou plusieurs paires propriété/valeur comme paramètres :

Dans le paramètre propriété, passez le libellé de la propriété à créer. Notez que le libellé du paramètre propriété est sensible à la casse.
Dans le paramètre valeur, passez la valeur que vous souhaitez fixer à la propriété. Plusieurs types de données sont supportés. Notez que :
- si vous passez un pointeur, il est récupéré tel quel ; il sera évalué lors de l'utilisation de commandes telles que JSON Stringify,
- les dates sont stockées sous forme de date "yyyy-mm-dd" ou de chaîne au format "YYYY-MM-DDTHH:mm:ss.SSSZ" en fonction du paramétrage courant relatif au stockage des dates dans les objets (cf. Page Compatibilité). Lorsque vous convertissez des dates 4D en texte, avant de les stocker dans l'objet, par défaut, le programme utilise l'heure locale de la zone. Vous pouvez modifier ce comportement en utilisant le sélecteur Dates dans les objets de la commande FIXER PARAMETRE BASE.
- si vous passez une heure, elle est stockée en nombre de millisecondes (réel).

Exemple 1

Cette commande peut créer des objets vides ou des objets remplis :

 C_OBJET($obj1)

 C_OBJET($obj2)

 C_OBJET($obj3)

 $obj1:=Creer objet

  // $obj1 = {}

 $obj2:=Creer objet("name";"Smith")

  // $obj2 = {name:Smith}

 $obj3:=Creer objet("name";"Smith";"age";40)

  // $obj3 = {name:Smith,age:40}

Exemple 2

Création d'un nouvel objet avec un objet en paramètre valeur :

 C_OBJET($Children;$Contact)

 

  //Création d'un tableau objet

 TABLEAU TEXTE($arrChildren;3)

 $arrChildren{1}:="Richard"

 $arrChildren{2}:="Susan"

 $arrChildren{3}:="James"

 OB FIXER TABLEAU($Children;"Children";$arrChildren)

 

  //InitialIsation de l'objet

 $Contact:=Creer objet("FirstName";"Alan";"LastName";"Parker";"age";30;"Children";$Children)

  // $Contact = {FirstName:Alan,LastName:Parker,age:30,Children:{Children:[Richard,Susan,James]}}

Exemple 3

Cette commande est utile pour passer des objets en paramètres :

 C_OBJET($measures)

 $measures:=Lire mesures base(Creer objet("path";"DB.cacheReadBytes";"withHistory";Vrai;"historyLength";120))

Exemple 4

Avec cette commande, vous pouvez aisément gérer des objets en boucle :

 TABLEAU OBJET($refs;0)

 C_ENTIER LONG(vCounter)

 

 Boucle(vCounter;1;100)

    AJOUTER A TABLEAU($refs;Creer objet("line";"Line number "+Chaine(vCounter)))

 Fin de boucle

Voir aussi

Creer objet partage