CONFIRM

4D v18

CONFIRM


CONFIRM ( message {; OK button title {; cancel button title}} )

引数	型	説明
message	文字	確認ダイアログボックスに表示するメッセージ
OK button title	文字	OKボタンのタイトル
cancel button title	文字	キャンセルボタンのタイトル

説明

CONFIRM コマンドは、注意アイコンとメッセージ、OKボタン、キャンセルボタンで構成される確認ダイアログボックスを表示します。

message引数には表示するメッセージを渡します。このメッセージは最大255バイトまで指定可能ですが、表示されるメッセージがメッセージエリアに表示しきれない場合は、文字の幅にもよりますが途中で切り取られます。

デフォルトでは、OKボタンのタイトルは“OK”で、キャンセルボタンのタイトルは"キャンセル"です。これらのボタンタイトルを変更するには、オプションのok button titleやcancel button title引数に新しいカスタムボタンタイトルを指定します。必要であれば、渡したカスタムタイトルの幅に応じて、ボタンの幅を左方向にリサイズします。

OKボタンはデフォルトボタンです。ユーザがOKボタンをクリックするかEnterキーを押してダイアログを受け入れると、OKシステム変数が1に設定されます。ユーザがキャンセルボタンをクリックしてダイアログをキャンセルすると、OKシステム変数は0に設定されます。

Tip: フォームあるいはオブジェクトメソッド中で、On Activate や On Deactivateを処理するセクションからCONFIRMコマンドを呼ばないでください。これは永久ループを引き起こします。

例題 1

以下のコードを実行すると:

 CONFIRM("WARNING: You will not be able to revert this operation.")

 If(OK=1)

    ALL RECORDS([Old Stuff])

    DELETE SELECTION([Old Stuff])

 Else

    ALERT("Operation canceled.")

 End if

以下のような確認ダイアログボックスを表示します(Windows環境):

例題 2

このコードを実行すると:

CONFIRM("Do you really want to close this account?";"Yes";"No")

Windowsにおいて以下のような確認ダイアログボックスを表示します:

例題 3

国際的なマーケットを考慮した4Dアプリケーションを書くとします。インターフェースの文字列とともに、ターゲット言語の翻訳文をXLIFF ファイルに書き込んだとします。その場合、以下のコードを実行すると:

 C_TEXT($title;$yes;$no)

 $title:=Get localized string("add_Memo")

 $yes:=Get localized string("yes")

 $no:=Get localized string("no")

 CONFIRM($title;$yes;$no)

以下のようなフランス語の確認ダイアログを(Windows 環境下において)表示することができます:

注: xliff を使用したデータベースのローカライズについての詳細な情報については、付録 B: XLIFFアーキテクチャーの章を参照してください。

例題 4

このコードを実行すると:

 CONFIRM("WARNING: If your pursue this operation, some records will be "+"irremediably affected."+\

 Char(13)+"What do you want to do?";"Do NOT continue";"Continue")

以下のような確認ダイアログボックスを表示します(Windows環境):

参照

ALERT
Request