4D v17
WP SET ATTRIBUTES
- 4D Write Pro
-
- 4D Write Pro - Langage
-
- A propos des objets 4D Write Pro
- Utiliser les commandes du thème Objets (Formulaires)
- Utiliser les commandes du thème Texte multistyle
- Accéder au contenu des documents par programmation
- Constantes 4D Write Pro
- WP Add picture
- WP CREATE BOOKMARK
- WP Create paragraph range
- WP Create picture range
- WP Create range
- WP Create table rangeNew
- WP DELETE BOOKMARK
- WP EXPORT DOCUMENT
- WP EXPORT VARIABLE
- WP GET ATTRIBUTES
- WP Get body
- WP Get bookmark range
- WP GET BOOKMARKS
- WP Get element by IDNew
- WP Get elementsNew
- WP Get footer
- WP Get frame
- WP Get header
- WP Get page count
- WP Get positionNew
- WP Get selection
- WP Get textNew
- WP Import document
- WP INSERT BREAKMod
- WP INSERT DOCUMENT
- WP INSERT PICTURE
- WP Insert table
- WP Is font style supported
- WP New
- WP PRINT
- WP RESET ATTRIBUTES
- WP SELECT
- WP SET ATTRIBUTES
- WP SET FRAME
- WP SET TEXTNew
- WP Table append row
- WP Table get cellsMod
- WP Table get columnsMod
- WP Table get rowsMod
- WP USE PAGE SETUP
- Attributs 4D Write Pro
WP SET ATTRIBUTES
| WP SET ATTRIBUTES ( objCible ; nomAttribut ; valeurAttribut {; nomAttribut2 ; valeurAttribut2 ; ... ; nomAttributN ; valeurAttributN} ) | ||||||||
| Paramètre | Type | Description | ||||||
| objCible | Objet |
|
Plage ou référence d'élément ou document 4D Write Pro | |||||
| nomAttribut | Texte |
|
Nom d'attribut dont vous souhaitez modifier la valeur | |||||
| valeurAttribut | Texte, Numérique, Tableau entier long, Tableau réel, Image, Date |
|
Nouvelle valeur de l'attribut | |||||
La commande WP SET ATTRIBUTES vous permet de fixer la valeur d'un ou plusieurs attribut(s) dans une plage, un élément référencé ou un document 4D Write Pro. Cette commande donne accès à tous les types d'attributs internes de 4D Write Pro : caractère, paragraphe, tableau, document ou image.
Dans objCible, vous pouvez passer :
- un objet plage 4D Write Pro, ou
- une référence d'élément (en-tête / pied / corps / tableau / ligne / image en ligne ou ancrée / paragraphe), ou
- un document 4D Write Pro.
Dans nomAttribut, passez le nom de l'attribut à modifier pour la cible et dans valeurAttribut, passez la valeur à définir. Pour une liste complète des attributs que vous pouvez passer dans nomAttribut ainsi que les valeurs que vous pouvez passer dans valeurAttribut, veuillez vous référer à la section Attributs 4D Write Pro.
Vous pouvez passer autant de paires nomAttribut / valeurAttribut que vous voulez.
Note : Si vous devez définir plusieurs attributs pour la même cible, il est plus optimisé d'effectuer un appel unique à WP SET ATTRIBUTES avec toutes les paires attributs/valeurs, que d'appeler plusieurs fois WP SET ATTRIBUTES.
Dans cette zone 4D Write Pro, vous sélectionnez un mot :
Si vous exécutez le code suivant :
$range:=WP Get selection(*;"WParea") //récupérer la plage sélectionnée
// fixer le décalage d'ombre en pt pour la sélection
WP SET ATTRIBUTES($range;wk text shadow offset;1)
//définir la marge intérieure du paragraphe
WP SET ATTRIBUTES($range;wk padding;1)
//définir une bordure de 10 pt
WP SET ATTRIBUTES($range;wk border style;wk solid;wk border width;10)
//définir les couleurs de bordure
WP SET ATTRIBUTES($range;wk border color;"blue";wk border color bottom;"#00FA9A";wk border color right;"#00FA9A")Vous obtenez le résultat suivant :
Cet exemple illustre le rôle des constantes wk inside et wk outside :
$wpRange:=WP Get selection(writeProdoc)
WP SET ATTRIBUTES($wpRange;wk border style+wk inside;wk dotted)
WP SET ATTRIBUTES($wpRange;wk border style+wk outside;wk solid)
WP SET ATTRIBUTES($wpRange;wk border color+wk outside;"#00FA9A")En supposant que tout le contenu était sélectionné, le résultat est :
Vous souhaitez définir une image de fond pour le document :
C_OBJECT(WParea)
WParea:=WP New
READ PICTURE FILE("C:\\Pictures\\boats.jpg";$picture)
WP SET ATTRIBUTES(WParea;wk background image;$picture)Le résultat est le suivant :
Vous souhaitez définir une image de fond qui recouvre la totalité de la zone d'impression :
C_OBJECT(WParea)
WParea:=WP New
READ PICTURE FILE("C:\\Pictures\\boats.jpg";$picture)
WP SET ATTRIBUTES(WParea;wk background image;$picture)
WP SET ATTRIBUTES(WParea;wk background clip;wk paper box)
WP SET ATTRIBUTES(WParea;wk background origin;wk paper box)Le résultat est le suivant :
Note : La valeur wk paper box peut être appliquée uniquement aux documents ou aux sections.
Vous voulez définir des tabulations à intervalles variés et utiliser différents caractères de conduite :
C_OBJECT(WParea)
ARRAY TEXT(_position;0)
ARRAY LONGINT(_type;0)
ARRAY TEXT(_leadings;0)
APPEND TO ARRAY(_position;"3cm")
APPEND TO ARRAY(_type;wk left)
APPEND TO ARRAY(_leadings;".")
APPEND TO ARRAY(_position;"7.5cm")
APPEND TO ARRAY(_type;wk right)
APPEND TO ARRAY(_leadings;".")
APPEND TO ARRAY(_position;"9cm")
APPEND TO ARRAY(_type;wk center)
APPEND TO ARRAY(_leadings;".")
APPEND TO ARRAY(_position;"12cm")
APPEND TO ARRAY(_type;wk decimal)
APPEND TO ARRAY(_leadings;"~")
APPEND TO ARRAY(_position;"2cm")
APPEND TO ARRAY(_type;wk left)
APPEND TO ARRAY(_leadings;"")
$range:=WP Get selection(WParea)
WP SET ATTRIBUTES($range;wk tab stop offsets;_position)
WP SET ATTRIBUTES($range;wk tab stop types;_type)
WP SET ATTRIBUTES($range;wk tab stop leadings;_leadings)Le résultat est du type :
Attributs 4D Write Pro
WP GET ATTRIBUTES
WP RESET ATTRIBUTES
Produit : 4D
Thème : 4D Write Pro - Langage
Numéro :
1342
Créé : 4D v15 R4
Modifié : 4D v16 R4
Modifié : 4D v16 R6
4D Write Pro ( 4D v17)
