WP Get elements

4D v17

WP Get elements


WP Get elements ( objRango {; tipoElemento} ) -> Resultado

Parámetro	Tipo	Descripción
objRango	Objeto	Rango o referencia del elemento o documento 4D Write Pro
tipoElemento	Entero largo	Tipo de elemento deseado a recuperar
Resultado	Collection	Colección que contiene referencias de elemento

Descripción

El comando WP Get elements devuelve una colección de objetos que contienen párrafos, imágenes, tablas y/o referencias de filas.

En el parámetro objRango, puede pasar:

un rango, o
una referencia de elemento (tabla / fila / párrafo / cuerpo / encabezado / pie de página), o
un documento 4D Write Pro

Si se pasa un rango digitado o una referencia, el comando devolverá una colección que solo contiene elementos del tipo correspondiente (a menos que especifique un tipo con el parámetro tipoElemento, ver abajo). De lo contrario, el comando devuelve una colección que contiene todos los elementos disponibles en objRango.

Opcionalmente, puede pasar el parámetro tipoElemento para especificar los tipos de elementos a devolver en la colección. Los siguientes tipos están disponibles:

Constante	Valor	Comentario
wk type default	0	Tipo de rango por defecto (valor para wk type)
wk type image	2	Imagen anclada (valor para wk type)
wk type image anchored	200	Referencia de imagen anclada para objetos de documento
wk type image inline	100	Referencia de imagen en línea para objetos de documento
wk type paragraph	1	Rango de tipo párrafo (valor para wk type)
wk type table	4	Referencia de tabla (valor para wk type)
wk type table row	5	Referencia de línea de tabla (valor para wk type)

Nota:

Si pasa el selector wk type default, el comando devuelve una colección no filtrada.
Si pasa el selector wk type paragraph, wk type image o wk type table, la colección devuelta contendrá solo elementos del tipo dado, incluso si difiere del tipo especificado en el parámetro tipoElemento.
Los elementos en la colección devuelta se ordenan según su orden de aparición en objRango, excepto cuando se pasa una referencia de documento 4D Write Pro. En este caso, los elementos se ordenarán por su ID.
Si un rango pasado en targetObj contiene un elemento que no está completamente contenido dentro del rango, el elemento completo se incluirá en los resultados. Por ejemplo, si el rango incluye parte de una tabla (pero no de toda la tabla), se devuelve la referencia para todo el elemento de la tabla, sin embargo, solo se incluyen las referencias de celda (párrafo) dentro del rango.

Ejemplo 1

Desea devolver una colección de todos los párrafos en un documento:

 C_COLLECTION($docElements)

 $docElements:=WP Get elements($myDoc;wk type paragraph)

  //devuelve una colección que contiene solo elementos de párrafo

Ejemplo 2

Usted desea alternar la alineación y el color de los párrafos en un documento:

 C_COLLECTION($col)

 C_OBJECT($obj)

 C_OBJECT($body)

 C_LONGINT($i;$n)

 $col:=New collection

 $body:=WP Get body(myDoc)

 $col:=WP Get elements($body;wk type paragraph)

 $i:=0

 $n:=$col.length

 For($i;0;$n-1)

    $obj:=$col[$i]

    WP RESET ATTRIBUTES($obj)

    WP SET ATTRIBUTES($obj;wk font bold;wk false)

    WP SET ATTRIBUTES($obj;wk font italic;wk false)

    If($i%2=0)

       WP SET ATTRIBUTES($obj;wk text align;wk left)

       WP SET ATTRIBUTES($obj;wk font bold;wk true)

       WP SET ATTRIBUTES($obj;wk text color;"#804040")

       WP SET ATTRIBUTES($obj;wk margin right;"5cm")

       WP SET ATTRIBUTES($obj;wk margin left;"1cm")

    Else

       WP SET ATTRIBUTES($obj;wk text align;wk right)

       WP SET ATTRIBUTES($obj;wk font italic;wk true)

       WP SET ATTRIBUTES($obj;wk text color;"#404020")

       WP SET ATTRIBUTES($obj;wk margin left;"5cm")

       WP SET ATTRIBUTES($obj;wk margin right;"1cm")

    End if

 End for

Ver también

WP Create table range
WP Get element by ID